Mẫu lập kế hoạch kinh doanh trên Excel: 6 tab, công thức và ví dụ quán cà phê, shop online

Bản kế hoạch kinh doanh bằng chữ (thị trường, khách hàng, đối thủ) trả lời câu hỏi "bán cho ai, vì sao người ta mua". Phần bảng tính trả lời câu hỏi còn lại: bán bao nhiêu thì đủ sống, cần bao nhiêu vốn, bao giờ hết lỗ. Phần này nên tách thành các tab, mỗi tab một việc:

Số tab

6 (có thể gộp còn 4)

Ô gõ tay

Chỉ ở tab Giả định, Chi phí

Khoảng kế hoạch

12 tháng, mỗi tháng một dòng

Kịch bản

Xấu · Cơ sở · Tốt

Hai tab đầu là chỗ bạn nghĩ nhiều nhất; bốn tab sau là công thức, làm một lần là xong. Phần dưới dựng từng tab theo ví dụ một quán cà phê nhỏ.

Đặt tên trang là GiaDinh (không dấu, không khoảng trắng cho dễ gõ công thức). Ô B1 là ô chọn kịch bản (danh sách thả xuống ba giá trị Xấu, Cơ sở, Tốt — xem cách tạo danh sách thả xuống). Dòng 2 là tiêu đề: A2 Giả định, B2 Đang dùng, C2 Xấu, D2 Cơ sở, E2 Tốt.

=INDEX(C3:E3; MATCH($B$1; $C$2:$E$2; 0))

Thử lại: B1 = "Cơ sở". MATCH tìm "Cơ sở" trong C2:E2 ra vị trí 2, INDEX lấy ô thứ 2 của C3:E3 là 50. Đổi B1 thành "Tốt" thì B3 thành 60, B4 thành 10%.

Định phí ở B8 không nên gõ một con số tròn. Lập danh sách ở trang ChiPhi (mặt bằng 18 triệu, lương 24 triệu, điện nước internet 5 triệu, khác 3 triệu trong ví dụ), cộng bằng =SUM(ChiPhi!B2:B5), rồi cho C8, D8, E8 cùng trỏ vào ô tổng đó. Cách tách định phí, biến phí và vì sao phí sàn, hoa hồng nên tính vào biến phí có ở bài cách tính điểm hoà vốn; còn biến phí lấy từ giá vốn thật thì xem cách tính giá vốn và lợi nhuận.

Trang KeHoach, mỗi tháng một dòng từ dòng 2 tới dòng 13. Cột: A Tháng (1–12), B Ly/ngày, C Doanh thu, D Biến phí, E Định phí, F Lãi tháng, G Lãi luỹ kế, H Tiền cuối tháng.

=ROUND(MIN(GiaDinh!$B$5; GiaDinh!$B$3*(1+GiaDinh!$B$4)^(A2-1)); 0)

=B2*GiaDinh!$B$9*GiaDinh!$B$6

=ROUND(C2*GiaDinh!$B$7; -3)

=GiaDinh!$B$8

=C2-D2-E2

=SUM($F$2:F2)

Kéo B2:G2 xuống tới dòng 13. Thử lại tháng 4 của kịch bản cơ sở: 50 × 1,08³ = 62,99 → 63 ly; doanh thu 63 × 30 × 40.000 = 75.600.000; biến phí 34% = 25.704.000; lãi = 75.600.000 − 25.704.000 − 50.000.000 = −104.000 — gần hoà vốn nhưng vẫn lỗ. Tháng 5: 68 ly, doanh thu 81.600.000, lãi 3.856.000.

Mùa vụ. Quán gần trường học vắng dịp hè, shop quà tặng đông dịp Tết. Thêm cột I Hệ số mùa (1 là bình thường, 1,3 là tháng cao điểm, 0,8 là tháng thấp điểm) rồi nhân vào C2: =B2*GiaDinh!$B$9*GiaDinh!$B$6*I2. Hệ số này lấy từ sổ bán hàng năm trước nếu có, chưa có thì để 1 hết thay vì đoán.

Lãi lỗ cho biết bạn có đang kiếm được tiền không. Dòng tiền cho biết tài khoản còn bao nhiêu — và một kế hoạch có lãi vẫn có thể chết vì hết tiền giữa chừng. Khác nhau ở các khoản như tiền đầu tư ban đầu, tiền cọc mặt bằng, nhập hàng trả trước, sàn thương mại điện tử trả tiền chậm.

=GiaDinh!$B$10-GiaDinh!$B$11+G2

Thử lại: tháng 1 lãi −10.400.000, nên H2 = 350.000.000 − 260.000.000 − 10.400.000 = 79.600.000. Tháng 4 lãi luỹ kế −21.800.000, H5 = 68.200.000 — đây là đáy của kịch bản cơ sở. Công thức gọn này đúng khi mọi doanh thu thu tiền ngay và chi phí trả trong tháng, như quán cà phê. Kinh doanh có nhập hàng trước hay bị nợ tiền thì cần thêm cột tiền vào, tiền ra riêng — xem ví dụ shop online bên dưới.

=MIN(H2:H13)

=MAX(0; -MIN(H2:H13))

Phần lý thuyết điểm hoà vốn, biên lợi nhuận góp và biên an toàn đã có đầy đủ trong bài cách tính điểm hoà vốn. Trong kế hoạch kinh doanh chỉ cần vài ô đọc từ tab Giả định và tab KeHoach:

=ROUNDUP(GiaDinh!B8/(GiaDinh!B6*(1-GiaDinh!B7))/GiaDinh!B9; 0)

=IF(COUNTIF(KeHoach!F2:F13;">0")=0; "Chưa có lãi"; MINIFS(KeHoach!A2:A13; KeHoach!F2:F13; ">0"))

=IF(MAX(KeHoach!G2:G13)<GiaDinh!B11; "Sau tháng 12"; MINIFS(KeHoach!A2:A13; KeHoach!G2:G13; ">="&GiaDinh!B11))

Thử lại: mỗi ly góp 40.000 × (1 − 34%) = 26.400đ. 50.000.000 ÷ 26.400 = 1.894 ly mỗi tháng, chia 30 ngày = 63,1 → 64 ly/ngày. Bảng kế hoạch khớp: tháng 4 bán 63 ly còn lỗ 104.000, tháng 5 bán 68 ly là tháng đầu có lãi, nên ô thứ hai ra 5. Lãi luỹ kế 12 tháng là 131.808.000, chưa đủ 260 triệu đầu tư, ô thứ ba ra "Sau tháng 12". Nếu giữ 100 ly/ngày, mỗi tháng lãi 29.200.000, cần thêm 5 tháng nữa: hoàn vốn khoảng tháng 17.

Đổi ô B1 qua lại giữa Xấu, Cơ sở, Tốt và chép kết quả các ô tổng vào một bảng nhỏ (dán dạng giá trị). Ba kịch bản đặt cạnh nhau cho bạn câu trả lời mà một con số dự báo đơn lẻ không cho được.

Đọc bảng: ở kịch bản xấu, quán vẫn có lãi từ tháng 11 nhưng tài khoản âm từ tháng 7, thấp nhất −11.624.000 ở tháng 10. Nghĩa là với 350 triệu vốn, bạn cần dự phòng ít nhất khoảng 12 triệu nữa (thực tế nên để dư hơn), hoặc đặt sẵn một mốc cắt lỗ: "tới tháng 6 chưa đạt 55 ly/ngày thì giảm giờ mở cửa, cắt một ca nhân viên". Thử lại tháng 10 kịch bản xấu: 40 × 1,05⁹ = 62,05 → 62 ly; lãi = 62 × 26.400 × 30 − 50.000.000 = −896.000; luỹ kế 10 tháng −101.624.000, tiền = 90.000.000 − 101.624.000 = −11.624.000.

Ngoài ba kịch bản, thử thêm từng biến một để biết kế hoạch nhạy với cái gì nhất: tăng giá mặt bằng 20%, biến phí lên 38% vì giá cà phê nhân tăng, giảm giá 10% để chạy khuyến mãi. Biến nào làm tháng có lãi lùi xa nhất là biến cần theo dõi sát nhất khi đã mở cửa.

Shop online khác quán cà phê ở chỗ phải nhập hàng trước khi bán. Giả định: tháng đầu 220 đơn, tăng 15% mỗi tháng, giá trị đơn bình quân 250.000đ; giá vốn 45% doanh thu; phí sàn, thanh toán, đóng gói, quảng cáo cộng lại 25% doanh thu; định phí 15.000.000/tháng; vốn 80.000.000; hàng của tháng sau phải nhập và trả tiền ngay trong tháng này. Tất cả là giả định — phí sàn thật xem trong biểu phí hiện hành của từng sàn.

=ROUND(220*(1+15%)^(A2-1); 0)

Tab Dòng tiền của shop cần tách tiền ra: Tiền cuối tháng = tiền đầu tháng + doanh thu − phí 25% − định phí − tiền nhập hàng cho tháng sau. Tháng 0 (trước khi mở bán) đã chi 24.750.000 nhập hàng cho tháng 1, nên đầu tháng 1 còn 55.250.000.

Thử lại tháng 2: lãi = 63.250.000 − 28.462.500 − 15.812.500 − 15.000.000 = 3.975.000. Tiền = 53.037.500 + 63.250.000 − 15.812.500 − 15.000.000 − 32.737.500 = 52.737.500 — thấp hơn tháng 1 dù tháng 2 có lãi, vì đơn tăng thì tiền nhập hàng ứng trước cũng tăng. Bán càng nhanh, shop càng cần nhiều tiền chôn trong hàng; nếu sàn giữ tiền thêm vài ngày trước khi chuyển về, chỗ hụt còn lớn hơn. Cách giữ tồn kho vừa đủ có ở bài quản lý tồn kho bằng Excel.

Kế hoạch chỉ có ích khi mỗi tháng bạn đặt số thực tế cạnh số dự kiến. Thêm vào tab KeHoach các cột Doanh thu thực, Lãi thực, Chênh lệch (=Thực − Kế hoạch) và tô đỏ khi doanh thu thực thấp hơn kế hoạch quá 10%. Ba tháng liên tiếp đi theo đường kịch bản xấu là lúc mở lại tab Giả định, sửa số và tính lại vốn cần thêm.

Cái khó là có số thực đúng mỗi tháng: doanh thu, giá vốn, chi phí vận hành, tiền còn trong két và tài khoản. Nếu bán tại cửa hàng hoặc bán sỉ, ghi bán hàng bằng một hệ thống tính sẵn lãi theo tháng sẽ đỡ việc cộng tay từ sổ — xem thêm quản lý bán hàng bằng Google Sheets.

Phần chữ của kế hoạch thường kết thúc bằng một danh sách việc trước ngày khai trương: sửa mặt bằng, mua máy, tuyển người, đăng ký hộ kinh doanh, chạy thử menu. Mỗi việc một người phụ trách và một hạn — có thể theo dõi bằng mẫu kế hoạch công việc tuần hoặc Bảng theo dõi công việc PRO có Gantt và nhắc hạn.

• Gõ số tay rải rác khắp file. Giá bán gõ lại ở ba tab, đổi một chỗ quên hai chỗ. Mọi giả định phải nằm ở một tab, các tab khác chỉ tham chiếu.
• Tháng đầu đã đông như tháng thứ 10. Quán mới thường cần vài tháng để có khách quen; kế hoạch bắt đầu từ mức bán tối đa gần như chắc chắn sai.
• Quên các khoản ra một lần: tiền cọc mặt bằng, phí sửa chữa, đồng phục, tiền hàng tồn ban đầu. Chúng không nằm trong lãi lỗ nhưng làm tài khoản hụt ngay tháng 0.
• Không có tiền dự phòng. Kịch bản cơ sở vừa đủ tiền nghĩa là chỉ cần chậm hơn dự kiến một chút là thiếu. Lấy kịch bản xấu làm mức vốn tối thiểu.
• Số ra 0 hoặc lỗi vì số dạng chữ khi dán từ tin nhắn, file khác: xem sửa lỗi SUM bằng 0.

• Cách tính điểm hoà vốnĐịnh phí, biến phí, biên góp, biên an toàn
• Cách tính giá vốn và lợi nhuậnGiá vốn bình quân, markup và margin, lãi ròng
• Cách tạo biểu đồ trong Google SheetsVẽ đường tiền cuối tháng của 3 kịch bản
• Hướng dẫn Bán hàng 360 PROCài web app, báo cáo lãi và dòng tiền