Cách quản lý đơn hàng Shopee, TikTok Shop, Lazada bằng Google Sheets: gộp đơn, đối soát tiền sàn, lãi thật từng đơn

Mỗi sàn có trang quản lý đơn riêng, báo cáo riêng, cách gọi phí riêng. Bán trên một sàn thì xem trên app là đủ. Bán từ hai sàn trở lên, ba câu hỏi bắt đầu khó trả lời: tháng này lãi thật bao nhiêu, sàn nào lãi hơn, và còn bao nhiêu hàng để bán chung cho cả ba nơi.

Nguồn dữ liệu

File đơn + báo cáo thanh toán tải từ trang người bán

Lãi thật mỗi đơn

Tiền sàn trả về − giá vốn − đóng gói

Khoá chung

Mã đơn sàn và mã hàng (SKU)

Ví dụ trong bài

Đơn 250.000đ → lãi thật 67.050đ

Một bảng chung giải quyết cả ba: mỗi dòng là một món hàng trong một đơn, có cột Sàn, Mã đơn, SKU. Từ đó cộng doanh thu theo sàn, khớp tiền về theo mã đơn, trừ kho theo SKU. Nếu bạn chưa có sổ bán hàng cơ bản, đọc trước cách quản lý bán hàng bằng Google Sheets — bài này nối tiếp phần bán online.

Cả ba sàn đều cho tải danh sách đơn ra file Excel trong trang quản lý đơn của trang người bán (Kênh Người Bán của Shopee, Seller Center của TikTok Shop và Lazada). Tên nút và vị trí đổi theo phiên bản giao diện, nên mô tả chung thế này:

1. Vào mục quản lý đơn hàng, chọn khoảng ngày (ví dụ cả tuần trước) và trạng thái (tất cả, để thấy cả đơn huỷ, hoàn).
2. Bấm xuất hoặc tải xuống, đợi sàn tạo file rồi tải về máy.
3. Trong Google Sheets, tạo tab theo tên sàn (Shopee, TikTok, Lazada) và dán đè dữ liệu mới vào tab đó mỗi lần tải. Hoặc dùng Tệp › Nhập để đưa file vào đúng tab.
4. Ghi lại cột nào là Mã đơn, Ngày đặt, SKU, Số lượng, Giá bán, Trạng thái trong file của từng sàn. Ba sàn đặt cột khác nhau và có thể đổi khi sàn cập nhật mẫu file.

File đơn thường có mỗi dòng là một sản phẩm trong đơn: đơn có 3 món thì mã đơn lặp lại 3 dòng. Đây đúng là dạng bảng bạn cần, đừng gộp tay về một dòng mỗi đơn.

Tạo tab DonGop với 7 cột cố định: A Sàn, B Mã đơn, C Ngày đặt, D SKU, E Số lượng, F Giá bán, G Trạng thái. Ô A2 dùng một công thức lấy các cột cần từ ba tab sàn và xếp chồng lên nhau:

=VSTACK(
 FILTER(HSTACK(IF(Shopee!A2:A<>""; "Shopee"; ""); CHOOSECOLS(Shopee!A2:Z; 1; 3; 5; 6; 8; 2)); Shopee!A2:A<>"");
 FILTER(HSTACK(IF(TikTok!A2:A<>""; "TikTok Shop"; ""); CHOOSECOLS(TikTok!A2:Z; 1; 4; 7; 9; 10; 2)); TikTok!A2:A<>"");
 FILTER(HSTACK(IF(Lazada!A2:A<>""; "Lazada"; ""); CHOOSECOLS(Lazada!A2:Z; 2; 5; 6; 8; 9; 3)); Lazada!A2:A<>"")
)

Công thức đọc như sau: CHOOSECOLS nhặt đúng 6 cột theo thứ tự chung, HSTACK gắn thêm cột tên sàn ở đầu, FILTER bỏ dòng trống, VSTACK xếp ba khối chồng lên nhau. Dùng HSTACK thay cho dấu ngoặc nhọn { } vì ở vùng Việt Nam dấu nối cột trong mảng là dấu gạch chéo ngược, rất dễ gõ sai. Cột A2:A trong FILTER là cột mã đơn của file sàn — đổi nếu mã đơn không nằm ở cột A.

Thêm hai cột tính ngay cạnh, cho từng dòng hàng. Tab HangHoa có A = SKU, B = tên, C = giá vốn một đơn vị (cách tính giá vốn bình quân khi nhập nhiều giá xem ở cách tính giá vốn và lợi nhuận).

=ARRAYFORMULA(IF(B2:B=""; ; E2:E*F2:F))

=ARRAYFORMULA(IF(B2:B=""; ; E2:E*IFERROR(VLOOKUP(D2:D; HangHoa!A:C; 3; 0); 0)))

Giá bán trên đơn chưa phải tiền của bạn. Trước khi chuyển tiền về ví hoặc tài khoản, sàn trừ nhiều khoản. Các khoản hay gặp:

Cách làm không cần nhớ công thức phí của sàn: tải báo cáo thanh toán / doanh thu theo kỳ trong trang người bán (file này có số tiền cuối cùng sàn trả cho từng mã đơn), rồi dán hai cột Mã đơn và Số tiền thanh toán vào tab TienVe. Sàn đã tự trừ mọi phí; bạn chỉ khớp theo mã đơn.

Mỗi tháng làm thêm một phép kiểm tổng: tổng cột tiền về của một sàn trong kỳ phải khớp với tổng số tiền sàn đã chuyển vào tài khoản ngân hàng của bạn (sau khi trừ số dư còn trong ví). Lệch thì tìm đơn chưa về tiền hoặc khoản bị trừ riêng như phí quảng cáo.

Tạo tab LaiDon, mỗi mã đơn một dòng. Ô H1 là chi phí đóng gói trung bình mỗi đơn (hộp, băng keo, giấy gói), ví dụ 5.000.

Thử lại với đơn trong hình: TienVe có mã đơn đó với 192.050; DonGop có một dòng SKU giá vốn 120.000, số lượng 1, nên D2 = 120.000. E2 = 192.050 − 120.000 − 5.000 = 67.050đ. Biên lãi so với giá bán: 67.050 ÷ 250.000 = 26,8%. Nếu chỉ lấy giá bán trừ giá vốn, bạn tưởng lãi 130.000đ — gần gấp đôi thực tế.

=SUMIFS(LaiDon!E:E; LaiDon!B:B; J2; LaiDon!F:F; "Đã về")

Đơn chưa về tiền không có lãi (E để trống) — đừng ước lượng bằng giá bán, vì đơn đó còn có thể bị hoàn. Phí quảng cáo trên sàn thường trả riêng chứ không trừ theo đơn: cộng vào chi phí tháng rồi trừ ở lãi ròng, không chia vào từng đơn.

• Đơn huỷ trước khi giao: hàng chưa rời kho, không có tiền về. Không trừ kho; trong DonGop vẫn giữ dòng để đếm tỷ lệ huỷ.
• Đơn hoàn sau khi giao (trả hàng, giao thất bại): tiền về bằng 0 hoặc âm nếu sàn trừ phí vận chuyển chiều về. Khi nhận lại hàng, kiểm tình trạng: còn bán được thì cộng lại vào kho, hỏng thì ghi hao hụt.
• Hoàn một phần: khách trả một trong ba món — tiền về giảm, chỉ cộng lại kho món bị trả.

=COUNTIFS(LaiDon!B:B; J2; LaiDon!F:F; "Hoàn/huỷ - kiểm tra") / COUNTIF(LaiDon!B:B; J2)

Sau khi hàng hoàn về, liên hệ lại khách hỏi lý do hoặc ghi nhận để sửa mô tả sản phẩm. Quy trình nhắn tin, xin đánh giá, xử lý khiếu nại có ở bài chăm sóc khách hàng sau bán.

Khi cùng một kho hàng bán trên ba sàn và cả tại cửa hàng, số tồn thật chỉ có một. Thêm vào tab HangHoa: D = tồn đầu kỳ, E = nhập trong kỳ, G = hàng hoàn đã nhận lại.

=SUMIFS(DonGop!E:E; DonGop!D:D; A2; DonGop!G:G; "<>Đã huỷ")

=D2 + E2 - F2 + G2

Thử lại: tồn đầu 50, nhập 30, bán 42 trên ba sàn, nhận lại 2 hàng hoàn → 50 + 30 − 42 + 2 = 40. Số này cập nhật mỗi lần bạn dán file đơn mới, chứ không tự đẩy lên sàn. Vì vậy hãy sửa tồn trên từng sàn mỗi ngày và chừa một mức tồn an toàn (ví dụ để 5 cái không mở bán) để không bán quá số hàng đang có. Sổ nhập kho, kiểm kê, cảnh báo sắp hết có trong cách quản lý xuất nhập tồn kho bằng Excel.

Theo Nghị định 117/2025/NĐ-CP, hiệu lực từ 01/07/2025, sàn thương mại điện tử có chức năng đặt hàng và thanh toán phải khấu trừ, kê khai và nộp thay thuế GTGT và thuế TNCN cho hộ, cá nhân kinh doanh trên sàn, theo từng giao dịch. Với hàng hoá, tỷ lệ theo nghị định là 1% thuế GTGT và 0,5% thuế TNCN trên doanh thu giao dịch (hộ, cá nhân cư trú). Đơn bị huỷ hoặc trả hàng thì sàn bù trừ số thuế đã khấu trừ với các giao dịch khác.

Trong bảng tính, khoản này đã nằm trong số tiền sàn trả về nên bạn không trừ thêm lần nữa. Sàn cấp chứng từ khấu trừ thuế; giữ lại để đối chiếu cuối năm.

Tự dựng các tab trên là đủ cho shop vài chục đơn mỗi ngày. Khi bạn vừa bán tại quầy, vừa bán sỉ, vừa bán sàn từ chung một kho, Bán hàng 360 PRO gom việc này vào một file Google Sheets có web app:

• Nhập đơn sàn: chọn Shopee, TikTok Shop hoặc Lazada, chọn file .xlsx hoặc .csv tải từ trang người bán. Ứng dụng cho xem trước số đơn mới, số đơn đã nhập trước (cùng mã đơn sàn thì tự bỏ qua) và mã hàng lạ.
• Đơn có mã hàng không có trong danh mục thì chưa nhập — thêm mã ở Hàng hoá hoặc sửa SKU trên sàn rồi nhập lại; các đơn khác vẫn vào bình thường.
• Mỗi đơn sàn thành một chứng từ bán có kênh Shopee / TikTok Shop / Lazada, trừ kho chung với bán tại quầy và bán sỉ.
• Giá vốn bình quân di động theo từng kho tự tính; báo cáo bán hàng theo kênh, lãi theo mặt hàng, lãi ròng có dòng Phí sàn TMĐT trong chi phí vận hành.

Giới hạn cần biết: mẫu chưa kết nối API sàn nên bạn vẫn tải file đơn về rồi nhập; đối soát tiền về từng đơn theo báo cáo thanh toán vẫn làm như phần trên. Web app chạy trên Google Sheets (cài Apps Script khoảng 20–30 phút theo hướng dẫn). Bán vài trăm đơn mỗi ngày trên nhiều sàn và cần đồng bộ tồn tự động lên sàn thì nên dùng phần mềm bán hàng đa kênh có kết nối sàn.

• Cách quản lý bán hàng bằng Google SheetsSổ đơn, thu tiền, báo cáo cho cửa hàng nhỏ
• Cách tính giá vốn và lợi nhuậnGiá vốn bình quân, lãi gộp, lãi ròng
• Quản lý xuất nhập tồn kho bằng ExcelCông thức tồn, cảnh báo, kiểm kê
• Hướng dẫn cài Bán hàng 360 PROTừng bước cài web app trên Google Sheets