Cách quản lý bán hàng bằng Google Sheets cho cửa hàng nhỏ: sổ đơn, thu tiền, báo cáo

Nguyên tắc: thông tin nào cũng chỉ gõ một lần. Tên hàng, giá bán nằm ở tab Hàng hoá; sổ đơn chỉ ghi mã hàng và số lượng, phần còn lại tra sang. Đổi giá một chỗ là đơn mới lấy giá mới, không phải sửa ở mười nơi.

Số tab

5 (bỏ Thu tiền nếu không bán nợ)

Gõ hằng ngày

Chỉ tab Đơn bán

Hàm chính

XLOOKUP, SUMIFS

Ví dụ trong bài

18/10: 3 hoá đơn, 539.000đ

Trong công thức, tab đặt tên không dấu — HangHoa, KhachHang, DonBan, ThuTien — cho khỏi phải bọc dấu nháy.

Mỗi mặt hàng một dòng, cột A là mã hàng không trùng. Mã ngắn, viết hoa, không dấu (SUA01, GAO05) để gõ nhanh và tra không sai. Có mã vạch trên bao bì thì dùng luôn số mã vạch làm mã hàng.

• Bán theo hai đơn vị (lẻ chai và cả thùng): tạo hai mã riêng, ví dụ NUOC01 (chai) và NUOC01T (thùng 24 chai) với giá thùng riêng.
• Chặn gõ sai mã: ở cột Mã hàng của tab Đơn bán, đặt xác thực dữ liệu dạng danh sách lấy từ dải HangHoa!A2:A — người bán chọn từ danh sách thả xuống thay vì gõ tay.
• Không xoá mã đã bán: các đơn cũ đang tra theo mã đó; hàng ngừng bán thì đánh dấu ở một cột riêng.

Ghi mỗi hoá đơn một dòng kiểu "2 sữa, 1 mì" thì không cộng được doanh thu theo mặt hàng hay trừ tồn kho. Cách đúng: mỗi món hàng một dòng, các dòng cùng hoá đơn có chung Số HĐ.

Cột của tab DonBan: A Ngày, B Số HĐ, C Mã KH, D Mã hàng, E Tên hàng, F SL, G Đơn giá, H Giảm, I Thành tiền, J Thu. Khách vãng lai dùng chung mã KHLE. Ba công thức cho dòng 2, kéo xuống cho các dòng dưới:

E2: =XLOOKUP(D2;HangHoa!A:A;HangHoa!B:B;"Sai mã")
G2: =XLOOKUP(D2;HangHoa!A:A;HangHoa!D:D;0)
I2: =F2*G2-H2

File cũ hay Excel đời cũ không có XLOOKUP thì dùng VLOOKUP — số 4 là cột thứ 4 (Giá bán) tính từ cột A của vùng tra, FALSE là tìm khớp chính xác:

=IFERROR(VLOOKUP(D2;HangHoa!A:D;4;FALSE);0)

Thử lại: dòng HD0002 bán DAU01, SL 2, giảm 9.000. G lấy được 52.000, I = 2 × 52.000 − 9.000 = 95.000. Gõ nhầm DAU1 (thiếu số 0): E hiện "Sai mã", G = 0, I = −9.000 — số âm là dấu hiệu dễ thấy để sửa.

Tổng tiền một hoá đơn để báo khách hoặc ghi vào phiếu: cộng cột Thành tiền theo Số HĐ.

=SUMIFS(DonBan!I:I;DonBan!B:B;"HD0001")

Cột J (Thu) của tab DonBan là danh sách thả xuống ba giá trị: Tiền mặt, Chuyển khoản, Ghi nợ. Các dòng cùng hoá đơn ghi cùng một giá trị. Nhờ cột này, cuối ngày bạn biết trong két phải có bao nhiêu tiền và tài khoản phải nhận bao nhiêu.

• Tiền mặt: cuối ngày đếm két, so với tổng Tiền mặt ở tab Báo cáo cộng tiền lẻ đầu ngày.
• Chuyển khoản: ghi số hoá đơn vào nội dung chuyển khoản (khách quét mã có sẵn nội dung là tiện nhất — xem cách tạo mã QR chuyển khoản trong Google Sheets). Cuối ngày mở sao kê ngân hàng, dò từng khoản theo số hoá đơn.
• Ghi nợ: chỉ cho khách có mã trong tab Khách hàng. Khi khách trả, ghi một dòng vào tab ThuTien (Ngày, Mã KH, Số tiền).

Tab KhachHang tự tính tổng mua và số còn nợ của từng khách (cột A là Mã KH):

Tổng mua: =SUMIFS(DonBan!I:I;DonBan!C:C;A2)
Còn nợ:   =SUMIFS(DonBan!I:I;DonBan!C:C;A2;DonBan!J:J;"Ghi nợ")-SUMIFS(ThuTien!C:C;ThuTien!B:B;A2)

Thử lại: quán cà phê mã KH002 trong tháng mua ghi nợ 4 lần, tổng 1.250.000; ngày 15 trả 800.000. Còn nợ = 1.250.000 − 800.000 = 450.000. Cửa hàng còn theo dõi khách hỏi giá, báo giá chưa chốt thì đó là việc của sổ lead — xem quản lý khách hàng tiềm năng bằng Google Sheets.

Tab BaoCao: cột A là ngày (gõ 01/10/2026 rồi kéo xuống), các cột sau là công thức. Với dòng 2:

Doanh thu:    =SUMIFS(DonBan!I:I;DonBan!A:A;A2)
Tiền mặt:     =SUMIFS(DonBan!I:I;DonBan!A:A;A2;DonBan!J:J;"Tiền mặt")
Chuyển khoản: =SUMIFS(DonBan!I:I;DonBan!A:A;A2;DonBan!J:J;"Chuyển khoản")
Số hoá đơn:   =IFERROR(COUNTUNIQUE(FILTER(DonBan!B:B;DonBan!A:A=A2));0)

Doanh thu cả tháng: đặt ngày đầu tháng vào ô B1 (01/10/2026) rồi cộng từ ngày đó đến ngày cuối tháng. EOMONTH(B1;0) trả về 31/10/2026 nên công thức không cần sửa khi sang tháng 2 hay tháng 30 ngày:

=SUMIFS(DonBan!I:I;DonBan!A:A;">="&B1;DonBan!A:A;"<="&EOMONTH(B1;0))

Muốn biết bán có lời không thì thêm cột giá vốn vào sổ đơn (tra như Đơn giá, lấy cột E của HangHoa) rồi lấy doanh thu trừ giá vốn — cách tính và các bẫy có trong bài cách tính giá vốn và lợi nhuận.

Sổ đơn bán chính là sổ xuất kho: cộng cột SL theo mã hàng là ra số đã bán. Ghép với sổ nhập hàng và tồn đầu là có tồn kho từng mã, cảnh báo hàng sắp hết, kiểm kê. Phần này dài nên tách riêng: cách quản lý xuất nhập tồn kho bằng Excel, dùng được nguyên cho Google Sheets.

File như trên chạy tốt cho cửa hàng vài chục hoá đơn mỗi ngày, một người bán. Chỗ bắt đầu vướng:

• Chậm lúc đông khách: gõ mã vào ô bảng tính chậm hơn quét mã vạch, khách đứng chờ.
• Không in hoá đơn nhanh: phải dựng thêm tab mẫu in và chọn vùng in mỗi lần.
• Nhiều người cùng sửa một file: dễ gõ đè, xoá nhầm dòng của người khác, và ai cũng thấy giá vốn. Khoá được ô công thức (cách khoá ô) nhưng không ẩn được cột với người có quyền sửa.
• Giá vốn đứng yên: giá vốn gõ tay một lần trong danh mục, trong khi giá nhập mỗi đợt mỗi khác.
• File nặng dần: mỗi món bán là một dòng; vài chục nghìn dòng với hàng loạt SUMIFS quét cả cột thì mở file và tính lại chậm thấy rõ. Google Sheets giới hạn 10 triệu ô mỗi file.
• Mất mạng là ngừng ghi.

Bán hàng 360 PRO là mẫu HiTaVa làm cho trường hợp đó: dữ liệu vẫn nằm trong một file Google Sheets của bạn, nhưng người bán dùng một web app toàn màn hình mở từ menu của file. Những gì có trong mẫu:

• Bán tại quầy trên máy tính bảng, máy tính hoặc điện thoại: quét mã vạch bằng máy quét USB / Bluetooth hoặc chụp ảnh mã vạch bằng điện thoại, chọn biến thể và đơn vị, khách quen tích điểm.
• Thu tiền tiền mặt, chuyển khoản VietQR đúng số tiền đơn, thẻ, kết hợp hoặc ghi nợ; in hoá đơn K80, K58 qua hộp thoại in của trình duyệt, hoặc A5; mở ca, chốt ca đếm tiền theo mệnh giá.
• Mất mạng vẫn bán và in được: máy bán giữ danh mục, giá, tồn của kho mình tới 72 giờ, có mạng lại tự gửi đơn.
• Kho và công nợ: tới 5 kho / cửa hàng, giá vốn bình quân di động theo từng kho, phải thu phải trả theo tuổi nợ, nhắc nợ qua Zalo với tin soạn sẵn.
• Phân quyền: nhân viên đăng nhập bằng mã + PIN 6 số, không cần tài khoản Google, không thấy bảng tính; giá vốn ẩn với thu ngân; bán dưới giá vốn hay giảm quá mức cần quản lý duyệt.
• Báo cáo: trang Hôm nay (doanh thu, lãi gộp, nợ quá hạn), lãi theo mặt hàng, lãi lỗ theo tháng.

Giới hạn cần biết trước: cài Apps Script mất khoảng 20–30 phút theo hướng dẫn; đơn hiện ngay trên mọi màn hình của web app nhưng có thể mất tới khoảng 10 phút mới ghi vào tab bảng tính; số hoá đơn là số bán lẻ nội bộ, không phải hoá đơn điện tử; một file chứa tới 5.000 mã hàng, 3.000 khách, 80.000 dòng hàng. Mở bằng Excel thì các tab báo cáo vẫn tính bằng công thức, nhưng web app, máy bán, mã vạch, VietQR chỉ chạy trên Google Sheets.

• Cách quản lý xuất nhập tồn kho bằng ExcelSổ nhập, sổ xuất, tồn theo mã hàng, cảnh báo sắp hết, kiểm kê.
• Cách tính giá vốn và lợi nhuậnBiết mỗi đơn bán lời bao nhiêu.
• Tạo mã QR chuyển khoản trong Google SheetsMỗi hoá đơn một mã QR có sẵn số tiền.
• Hướng dẫn cài Bán hàng 360 PROTừng bước cài web app và máy bán tại quầy.