Quản lý khách hàng tiềm năng bằng Google Sheets: phễu, chấm điểm, nhắc gọi lại

Lead (khách hàng tiềm năng) là người đã để lại thông tin hoặc hỏi giá nhưng chưa mua. Họ tới từ quảng cáo Facebook, Zalo, website, người quen giới thiệu — và nằm rải rác trong tin nhắn của từng nhân viên. Khách hỏi giá rồi im 5 ngày, không ai nhớ gọi lại; nhân viên nghỉ việc, danh sách khách đi theo.

Một file lead tốt không chỉ là danh bạ. Nó phải trả lời được ba câu mỗi sáng: hôm nay gọi ai, lead nào đang nguội, và khách đang rơi ở bước nào của quá trình bán. Ba câu đó đều tính được bằng công thức nếu dữ liệu được ghi đúng cách.

Số bảng gõ tay

2 — Leads và Chăm sóc

Giai đoạn phễu

5 đang mở + Thắng / Thua

Hạng lead

A, B, C, D theo điểm 0–100

Dùng được trên

Google Sheets, Excel 365

Lỗi phổ biến nhất là ghi lịch sử chăm sóc vào một ô "Ghi chú" của dòng lead: "15/9 gọi không nghe, 17/9 gửi báo giá, 20/9 hẹn tuần sau". Không công thức nào đọc được ô đó. Tách ra mỗi lần liên hệ một dòng ở bảng riêng, file mới đếm được số lần gọi, lần gặp được, ngày liên hệ gần nhất.

Mã lead (L-0001, L-0002…) là thứ nối hai bảng. Đừng dùng họ tên làm khoá: hai khách cùng tên "Nguyễn Văn Nam" là chuyện thường. Ở bảng Chăm sóc, nhân viên chọn mã lead rồi ghi kết quả; thời điểm ghi cả ngày lẫn giờ.

Giai đoạn là cột quan trọng nhất của bảng Leads. Mỗi giai đoạn phải có định nghĩa rõ để hai nhân viên không hiểu khác nhau:

=IF(D2="";"";LET(s;REGEXREPLACE(D2&"";"[^0-9]";"");IF(LEFT(s;2)="84";"0"&MID(s;3;20);IF(LEN(s)=9;"0"&s;s))))

Thử: "+84 909.123.456" → bỏ ký tự lạ còn 84909123456 → bắt đầu bằng 84 nên thành 0909123456. "909123456" chỉ có 9 số → thêm 0 → 0909123456. Ba cách gõ khác nhau ra cùng một số.

=IF(L2="";"";IF(COUNTIF(L$2:L2;L2)>1;"Trùng";""))

=IF(COUNTIF('Chăm sóc'!B$2:B$5000;A2)=0;"";MAXIFS('Chăm sóc'!A$2:A$5000;'Chăm sóc'!B$2:B$5000;A2))

=IF(A2="";"";LET(h;XLOOKUP(A2;'Chăm sóc'!B$2:B$5000;'Chăm sóc'!G$2:G$5000;"";0;-1);IF(N(h)=0;"";h)))

=IF(A2="";"";TODAY()-INT(IF(N2="";B2;N2)))

Khi có 50 lead đang mở, không ai gọi kỹ được cả 50. Chấm điểm giúp xếp thứ tự: cộng điểm theo nguồn, ngân sách, số lần gặp được; trừ điểm khi lead bị bỏ quên. Bảng điểm dưới đây là ví dụ — mỗi ngành mỗi khác.

Đặt bảng điểm ở tab Cài đặt: hai cột Nguồn – Điểm, đặt tên dải ô là DiemNguon; hai cột Ngân sách – Điểm, tên DiemNganSach (Dữ liệu › Dải ô được đặt tên). Rồi:

=IF(A2="";"";MAX(0;MIN(100;IFERROR(VLOOKUP(E2;DiemNguon;2;FALSE);0)+IFERROR(VLOOKUP(G2;DiemNganSach;2;FALSE);0)+MIN(20;5*COUNTIFS('Chăm sóc'!B$2:B$5000;A2;'Chăm sóc'!E$2:E$5000;"Gặp được"))-IF(P2>7;10;0))))

=IF(Q2="";"";IFS(Q2>=70;"A";Q2>=50;"B";Q2>=30;"C";TRUE;"D"))

Kiểm tra với lead L-0012 trong hình: nguồn Gọi đến 20 + ngân sách trên 200 triệu 30 + gặp được 4 lần 5 × 4 = 20 → 70 điểm, hạng A. Lead L-0047: Facebook Ads 10 + dưới 10 triệu 0 + gặp 1 lần 5 − im lặng 9 ngày 10 → 5 điểm, hạng D.

Sau 2–3 tháng, đo xem điểm có đoán đúng không: tỉ lệ thắng của hạng A phải cao hơn hạng B, B cao hơn C. Nếu không, nghĩa là bảng điểm đang thưởng sai thứ — chỉnh điểm nguồn hoặc ngân sách.

=IFERROR(COUNTIFS(Leads!R$2:R$1000;"A";Leads!I$2:I$1000;"Thắng")/(COUNTIFS(Leads!R$2:R$1000;"A";Leads!I$2:I$1000;"Thắng")+COUNTIFS(Leads!R$2:R$1000;"A";Leads!I$2:I$1000;"Thua"));"")

Tạo tab Hôm nay. Thay vì mỗi nhân viên tự lọc bảng Leads, một công thức gom sẵn mọi lead có hẹn tới hôm nay hoặc đã quá hẹn, chưa thắng chưa thua, hẹn cũ nhất lên đầu:

=IFERROR(SORT(CHOOSECOLS(FILTER(Leads!A2:O1000; Leads!O2:O1000<>""; Leads!O2:O1000<=TODAY(); Leads!I2:I1000<>"Thắng"; Leads!I2:I1000<>"Thua");1;3;4;8;9;15);6;TRUE);"Hôm nay không có hẹn")

=IFERROR(FILTER(Leads!C2:C1000; Leads!A2:A1000<>""; Leads!N2:N1000=""; NOW()-Leads!B2:B1000>2/24);"Không có lead mới nào quá hạn")

=IFERROR(FILTER(Leads!C2:C1000; Leads!A2:A1000<>""; Leads!P2:P1000>7; Leads!I2:I1000<>"Thắng"; Leads!I2:I1000<>"Thua");"Không có lead nguội")

1. 

   Khách hỏi giá rồi im 5 ngày — file tự nhắc gọi lại (Short)

   Xem trên YouTube ↗

Phễu "tích luỹ" đếm số lead đã từng tới mỗi bậc, kể cả lead sau đó thua. Đếm theo giai đoạn hiện tại thì sai: một lead thua ở bước Đàm phán vẫn là lead đã qua bước Báo giá. Vì vậy cần cột S — bậc cao nhất lead đã tới:

=IF(A2="";"";IF(I2="Thắng";6;IFERROR(MATCH(IF(I2="Thua";K2;I2);GiaiDoan;0);1)))

=COUNTIF(Leads!S$2:S$1000;">="&B2)

Đọc phễu: chia mỗi bậc cho bậc trước. Trong ví dụ, từ Đã liên hệ sang Đủ điều kiện chỉ còn 110/170 = 65% — mất 60 lead, nhiều nhất trong các bước. Câu hỏi tiếp theo là vì sao: đếm lý do thua của các lead thua ở bậc 2.

=COUNTIFS(Leads!I$2:I$1000;"Thua";Leads!J$2:J$1000;A2)

Nếu "Không có nhu cầu thật" đứng đầu, vấn đề nằm ở quảng cáo nhắm sai người. Nếu "Không liên lạc được" cao, vấn đề là gọi chậm — xem lại danh sách lead mới quá 2 giờ ở trên.

Bảng tính hợp với đội bán hàng nhỏ, quy trình đơn giản và muốn tự quyết dữ liệu nằm ở đâu. Đội đông, cần tổng đài gọi ra, tích hợp nhiều kênh và phân quyền chặt thì phần mềm CRM chuyên dụng phù hợp hơn. So sánh cụ thể: HiTaVa và Getfly CRM, mẫu Google Sheets hay phần mềm quản lý.

Phần việc nội bộ của đội — chuẩn bị tài liệu, chạy chiến dịch, làm báo giá — thì quản lý ở bảng việc riêng, xem quản lý công việc nhóm bằng Google Sheets.

• Quản lý công việc nhóm bằng Google SheetsBảng việc, trễ hạn, Kanban, nhắc hạn
• Google Sheets hay Excel?Làm chung, điện thoại, Apps Script
• Cách khoá ô công thức trong Google SheetsGiữ cột điểm, hạng không bị gõ đè
• Hướng dẫn cài đặt Quản lý Lead & Bán hàng PROCài Apps Script, form website, portal nhân viên