Quản lý lớp dạy thêm bằng Google Sheets: điểm danh, học phí, lương giáo viên

Lớp 10 học sinh thì cuốn sổ là đủ. Khi có 3–4 lớp, mỗi lớp một cách thu (lớp Toán thu theo tháng, lớp Vẽ thu theo buổi, lớp IELTS thu trọn khoá), có học sinh vào giữa tháng, có em nghỉ ốm xin học bù, có hai anh em học hai lớp — cuối tháng ngồi cộng tay là lúc sai. Sai một buổi thì phụ huynh nhắn hỏi, còn sai lương giáo viên thì mất lòng người dạy.

Cách chắc ăn là chỉ gõ một thứ: điểm danh. Học phí là phép tính trên số buổi; lương giáo viên là phép tính trên số buổi dạy. Không ai gõ tay số tiền.

Số bảng

8 (5 gõ tay, 3 tự tính)

Ký hiệu điểm danh

C, M, P, K, B, T

Cách tính học phí

Tháng, buổi, trọn khoá, gói buổi

Dùng được trên

Google Sheets, Excel

Hai nguyên tắc giống hệt file quản lý phòng trọ: mọi tháng nằm chung một bảng (có cột Kỳ, ví dụ 2026-10), và đổi giá thì thêm dòng giá mới có cột "áp dụng từ kỳ", không sửa dòng cũ — tăng học phí từ tháng 11 thì phiếu tháng 10 vẫn giữ nguyên.

Bảng Điểm danh: A Kỳ · B Mã HS · C Họ tên · D Lớp · E Cách tính · F đến Q là 12 ô buổi (B01…B12) · từ cột R là công thức. Mỗi buổi gõ một chữ:

Chọn F2:Q1000 › Dữ liệu › Xác thực dữ liệu › Menu thả xuống với 6 chữ trên, để không ai gõ "c" thường hay "x". Rồi đếm:

=COUNTIF(F2:Q2;"C")+COUNTIF(F2:Q2;"M")+COUNTIF(F2:Q2;"B")

=COUNTIF(F2:Q2;"P")
=COUNTIF(F2:Q2;"K")

=IFERROR(R2/(R2+S2+T2);"")

1. 

   Điểm danh & học phí lớp dạy thêm, có mã QR (Short)

   Xem trên YouTube ↗

Theo tháng. Học phí cố định mỗi tháng, bất kể tháng có 8 hay 9 buổi. Chỉ cần xử lý học sinh vào giữa tháng: tính theo số buổi còn lại trên số buổi chuẩn của lớp, làm tròn nghìn.

=ROUND(HocPhiThang*MIN(1;SoBuoiConLai/SoBuoiChuan);-3)

Ví dụ Toán 6, 900.000đ/tháng, 8 buổi chuẩn, học sinh vào từ buổi thứ 3: 900.000 × 6 / 8 = 675.000đ. MIN(1;…) giữ cho tháng có 9 buổi vẫn thu đúng 900.000đ chứ không thành 1.012.500đ.

Theo buổi. Có hai cách: thu sau (cuối tháng đếm buổi thực học) hoặc thu trước theo số buổi dự kiến rồi bù chênh lệch tháng sau. Thu trước giữ dòng tiền đều hơn:

=DonGia*(BuoiDuKien - (DuKienThangTruoc - BuoiTinhPhiThangTruoc))

Vẽ, 180.000đ/buổi: tháng 9 thu trước 8 buổi = 1.440.000đ, nhưng em nghỉ có phép 1 buổi nên chỉ tính 7. Tháng 10 dự kiến 8 buổi → 180.000 × (8 − (8 − 7)) = 1.260.000đ.

Trọn khoá. Một số tiền cho cả khoá, chia đợt. Mỗi đợt là một dòng phiếu riêng với hạn đóng riêng: IELTS 7.200.000đ chia 2 đợt là 3.600.000đ mỗi đợt.

Gói buổi. Phụ huynh mua trước 10, 12 hay 20 buổi, mỗi buổi có mặt trừ một. Cần cảnh báo trước khi hết để phụ huynh gia hạn:

=SoBuoiGoi-SUMIFS('Điểm danh'!R:R;'Điểm danh'!B:B;B2;'Điểm danh'!D:D;D2)
=IF(X2<=2;"Sắp hết gói";"")

Lớp thu theo tháng thường gặp câu hỏi "con nghỉ 2 buổi thì có trừ tiền không". Cần một quy định rõ, ghi trên phiếu đăng ký, và một hạn mức để tránh nghỉ tuỳ ý. Ba lựa chọn hay dùng:

• Bảo lưu — buổi nghỉ có phép (trong hạn mức, ví dụ tối đa 2 buổi/tháng) được trừ vào học phí tháng sau.
• Học bù — xếp học sinh vào một buổi khác hoặc lớp khác cùng trình độ, ghi B ở ô buổi đó. Đã học bù thì không bảo lưu nữa.
• Không trừ — học phí tháng là cố định; ghi rõ từ đầu để phụ huynh không bất ngờ.

=ROUND(HocPhiThang/SoBuoiChuan*MAX(0;MIN(2;S2-COUNTIF(F2:Q2;"B")));-3)

Toán 8, 1.200.000đ/tháng, 8 buổi → 150.000đ một buổi. Em nghỉ có phép 1 buổi, chưa học bù → tháng sau trừ 150.000đ, phải đóng 1.050.000đ. Nếu đã học bù buổi đó thì MAX(0;MIN(2;1−1)) = 0, không trừ.

Giảm anh chị em dựa vào mã gia đình. Ở bảng Học sinh, cột "Con thứ" = =COUNTIF(E$2:E2;E2) (E là mã gia đình) đếm đây là con thứ mấy trong nhà theo thứ tự nhập. Ví dụ quy định giảm 10% từ con thứ hai: Toán 6 của em thứ hai 675.000đ → giảm 67.500đ.

Phụ huynh có hai con học ba lớp không muốn nhận ba tin nhắn. Gộp một phiếu cho mỗi gia đình mỗi tháng: cộng thành tiền các dòng điểm danh cùng mã gia đình, cộng nợ kỳ trước, trừ tiền thừa. Nội dung chuyển khoản theo mẫu cố định "mã gia đình + kỳ", ví dụ GD0045 202610, để nhìn sao kê là biết tiền của nhà nào, tháng nào.

=IMAGE("https://img.vietqr.io/image/970436-0123456789-compact2.png?amount="&K2&"&addInfo="&ENCODEURL(L2)&"&accountName="&ENCODEURL("TRUNG TAM ABC"))

Đổi mã BIN, số tài khoản, tên cho đúng tài khoản của bạn, rồi quét thử bằng app ngân hàng trước khi gửi phụ huynh — phải hiện đúng tên chủ tài khoản và số tiền. Cách lấy mã BIN, các mẫu khung QR và lỗi hay gặp ở bài tạo mã QR chuyển khoản trong Google Sheets.

=SUMIFS('Học phí'!K:K;'Học phí'!B:B;A2)-SUMIFS('Thu tiền'!D:D;'Thu tiền'!B:B;A2)

Phụ huynh trả thiếu thì cứ ghi đúng số tiền nhận vào bảng Thu tiền; phần thiếu tự thành nợ và hiện ở phiếu tháng sau. Sắp bảng Công nợ theo số tiền giảm dần là có danh sách cần nhắc.

1. 

   Tạo mã QR chuyển khoản ngay trong Google Sheets — 1 hàm (Short)

   Xem trên YouTube ↗

Lương giáo viên ở trung tâm nhỏ thường theo một trong năm kiểu: theo buổi, theo giờ, theo phần trăm học phí thực thu của lớp, theo số học sinh có mặt, hoặc lương cứng cộng buổi. Cả năm kiểu đều đếm từ bảng Lịch học.

=COUNTIFS('Lịch học'!D:D;A2;'Lịch học'!A:A;">="&DauKy;'Lịch học'!A:A;"<="&CuoiKy;'Lịch học'!E:E;"Đã dạy")

Vì đếm theo giáo viên thực dạy chứ không theo giáo viên phân công, buổi dạy thay tự tính cho người đứng lớp. Ví dụ: cô Hà dạy 12 buổi, đơn giá 280.000đ/buổi → 3.360.000đ. Theo % thực thu: lớp thu được 13.500.000đ trong tháng, thoả thuận 40% → 5.400.000đ. Cộng phụ cấp, thưởng, trừ tạm ứng là ra thực nhận.

Giáo viên cộng tác nhận từ một mức nhất định có thể phải khấu trừ thuế thu nhập cá nhân — phần này kiểm tra với kế toán hoặc cơ quan thuế. Cách tính lương, bảo hiểm và thuế cho nhân viên chính thức ở bài cách tính lương nhân viên bằng Excel.

1. Mở tháng — tạo dòng điểm danh cho mỗi ghi danh đang học (và dòng buổi học trong Lịch học nếu dùng).
2. Điểm danh — sau mỗi buổi, giáo viên hoặc giáo vụ gõ ký hiệu.
3. Phát sinh — buổi huỷ, dạy thay, học bù, tài liệu, giảm giá.
4. Chốt học phí — phát phiếu cho từng gia đình, gửi tin kèm mã QR.
5. Thu tiền — mỗi lần nhận tiền một dòng; cuối tuần xem Công nợ.
6. Chốt lương — đếm buổi dạy, tính lương, ghi đã trả.
7. Báo cáo — doanh thu từng lớp, chuyên cần, học sinh nghỉ liên tiếp.

Khoá các cột công thức trước khi chia file cho giáo viên (cách khoá ô công thức), để không ai gõ đè lên học phí hay lương.

Dạy một hai lớp, một cách thu: file tự dựng như trên là đủ. Nhiều lớp, nhiều giáo viên, phụ huynh hỏi chuyên cần thường xuyên thì mẫu làm sẵn đỡ nhiều giờ mỗi tháng. Đang cân nhắc với phần mềm quản lý trung tâm thu phí hằng tháng, xem mẫu Google Sheets hay phần mềm quản lý.

• Tạo mã QR chuyển khoản trong Google SheetsHàm IMAGE, mã BIN, nội dung chuyển khoản
• Google Sheets hay Excel?Điện thoại, làm chung, Apps Script
• Cách quản lý phòng trọ bằng Google SheetsCùng cách tổ chức hoá đơn, thu tiền, công nợ
• Hướng dẫn cài đặt Quản lý lớp học PROCài Apps Script, thử mã QR, bật Web App