Quản lý công văn đi đến bằng Excel và Google Sheets: sổ theo dõi, hạn xử lý, tìm nhanh

Sếp hỏi "công văn số 1287 của bên Thép Bắc Hà đâu rồi?", văn thư lật sổ tay thấy đã nhận ngày 06/10, nhưng không ai nhớ đã chuyển cho ai, hạn trả lời là bao giờ. Sổ có ghi nhận văn bản, nhưng không ghi việc xử lý văn bản.

Một sổ theo dõi công văn dùng được phải trả lời ngay ba câu: văn bản đang ở chỗ ai, hạn khi nào, đã xong chưa. Muốn vậy bảng tính cần hai nhóm cột: nhóm vào sổ (gõ một lần lúc nhận) và nhóm xử lý (cập nhật khi giao việc, khi xong). Trạng thái hạn thì để công thức tính, không gõ tay.

Số sổ cần có

2 (đến, đi)

Cột tối thiểu theo mẫu NĐ 30

10 cột mỗi sổ

Số đến

Liên tiếp trong năm

Dùng được trên

Excel, Google Sheets

Nghị định 30/2020/NĐ-CP về công tác văn thư có mẫu Sổ đăng ký văn bản đến (Phụ lục IV) với tối thiểu 10 cột. Nghị định này bắt buộc với cơ quan nhà nước và doanh nghiệp nhà nước; công ty tư nhân không bắt buộc theo, nhưng đây là bộ cột đã được nghĩ kỹ, nên lấy làm khung rồi thêm các cột theo dõi xử lý.

Theo Điều 22 Nghị định 30/2020/NĐ-CP, số đến được lấy liên tiếp theo thứ tự và trình tự thời gian tiếp nhận văn bản trong năm, thống nhất giữa văn bản giấy và văn bản điện tử.

=IF(B2="";"";COUNTIFS(B$2:B2;">="&DATE(YEAR(B2);1;1);B$2:B2;"<="&DATE(YEAR(B2);12;31)))

=TEXT(COUNTIFS(B$2:B2;">="&DATE(YEAR(B2);1;1);B$2:B2;"<="&DATE(YEAR(B2);12;31));"0000")

Nếu công ty có nhiều chi nhánh cùng dùng một sổ, mỗi chi nhánh nên có dãy số riêng: thêm điều kiện cột Đơn vị vào COUNTIFS, và gắn mã đơn vị vào trước số (ví dụ HN-ĐẾN-2026-0234) để hai chi nhánh không trùng số.

Nghị định 30 yêu cầu văn thư trình văn bản đến trong ngày, chậm nhất là ngày làm việc tiếp theo; còn thời hạn giải quyết thì theo quy chế làm việc của từng cơ quan. Công ty tư nhân nên tự đặt hạn mặc định theo loại văn bản (ví dụ giấy mời 2 ngày, công văn 7 ngày) để bảng tính tự cộng.

Tạo một bảng nhỏ hai cột (Loại văn bản, Số ngày) và đặt tên vùng là HanMacDinh. Cột Hạn xử lý (H) để gõ tay khi lãnh đạo ghi hạn riêng; cột Hạn áp dụng (I) lấy hạn tay nếu có, không thì cộng theo loại:

=IF(B2="";"";IF(H2<>"";H2;B2+VLOOKUP(F2;HanMacDinh;2;FALSE)))

=IF(B2="";"";IF(H2<>"";H2;WORKDAY(B2;VLOOKUP(F2;HanMacDinh;2;FALSE);NgayLe)))

Mỗi văn bản chỉ nên có một người phụ trách chính ở cột Người xử lý; người phối hợp ghi ở cột khác. Hai tên trong một ô làm công thức đếm việc theo người sai, và khi trễ hạn không biết hỏi ai.

Cột Trạng thái hạn (K) là cột quan trọng nhất của sổ. Nó so Hạn áp dụng (I) với hôm nay và với Ngày hoàn tất (J), ra một trong năm nhãn:

=IF(I2="";"";IF(J2<>"";IF(J2<=I2;"Đúng hạn";"Trễ hạn");IF(TODAY()>I2;"Quá hạn";IF(I2-TODAY()<=3;"Sắp đến hạn";"Chưa đến hạn"))))

Thử với ví dụ trong hình, hôm nay là 16/10/2026: văn bản 0233 hạn 12/10, chưa xong, TODAY() > hạn nên ra "Quá hạn" (quá 4 ngày = TODAY() − I2). Văn bản 0234 hạn đúng hôm nay: chưa quá, còn 0 ngày ≤ 3 nên ra "Sắp đến hạn". Văn bản 0232 hạn 09/10, xong 12/10: có ngày hoàn tất và muộn hơn hạn nên ra "Trễ hạn".

Tô đỏ cả dòng quá hạn: chọn vùng A2:M (Google Sheets) hoặc A2:M3000 (Excel), vào Định dạng › Định dạng có điều kiện, chọn "Công thức tuỳ chỉnh là" (Excel: Use a formula…) và dán công thức dưới đây, chọn nền đỏ nhạt. Thêm một quy tắc nữa với "Sắp đến hạn" và nền vàng.

=$K2="Quá hạn"

=COUNTIFS(K2:K;"Quá hạn")
=COUNTIFS(G2:G;"Lan";K2:K;"Quá hạn")

=SORT(FILTER(A2:M;K2:K="Quá hạn");9;TRUE)

Mẫu Sổ đăng ký văn bản đi của Nghị định 30 cũng có tối thiểu 10 cột: số, ký hiệu văn bản; ngày tháng văn bản; tên loại và trích yếu; người ký; nơi nhận; đơn vị, người nhận bản lưu; số lượng bản; ngày chuyển; ký nhận; ghi chú. Trên bảng tính nên thêm các cột của quy trình soạn thảo: người soạn, người duyệt, trạng thái (Đang soạn → Chờ duyệt → Đã ban hành → Đã gửi) và hạn ban hành nếu có.

Số văn bản đi chỉ cấp sau khi đã ký (với văn bản giấy, chậm nhất là ngày làm việc tiếp theo) và đánh liên tiếp trong năm, bắt đầu từ 01 ngày 01/01. Đừng cấp số cho bản nháp: bản nháp bị huỷ để lại lỗ trong dãy số.

=MAXIFS(A2:A;B2:B;">="&DATE(YEAR(TODAY());1;1))+1

=TEXT(A2;"00")&"/"&D2&"-HTV"

Công văn thì ký hiệu không có phần tên loại mà là tên công ty và đơn vị soạn thảo, ví dụ 128/HTV-HCNS. Quy tắc đầy đủ về số, ký hiệu và chữ viết tắt từng loại văn bản sẽ có ở bài riêng về cách đánh số văn bản.

Khi sổ có vài nghìn dòng, Ctrl+F vẫn tìm được nhưng chỉ nhảy từng ô. Một ô tìm kiếm dùng FILTER cho ra mọi dòng khớp cùng lúc, tìm theo số đến, số ký hiệu, cơ quan gửi hoặc vài chữ trong trích yếu.

=FILTER(A2:M;ISNUMBER(SEARCH(O1;A2:A&" "&C2:C&" "&D2:D&" "&E2:E)))

SEARCH không phân biệt hoa thường, và để trống O1 thì hiện toàn bộ sổ. Nếu chỉ cần biết một văn bản đang ở chỗ ai, dùng XLOOKUP theo số ký hiệu: =XLOOKUP("1287/TBH-KD";C2:C;G2:G;"Không thấy").

1. 

   Sếp hỏi "công văn số 1287 đâu rồi?" — gom chồng giấy vào một màn hình (Short)

   Xem trên YouTube ↗

Một văn thư, một máy: Excel là đủ. Nhiều phòng ban cùng cập nhật, hoặc muốn tự gửi email nhắc hạn: Google Sheets tiện hơn. So sánh chi tiết hơn ở bài Google Sheets hay Excel.

Văn phòng nhỏ, vài chục công văn mỗi tháng: tự lập theo các công thức trên là ổn. Nhiều đơn vị, phòng ban, cần biết hồ sơ nào đang ở chỗ ai mà không cho mọi người mở bảng tính, thì mẫu làm sẵn đỡ nhiều công dựng và bảo trì. Cách cài đặt xem ở hướng dẫn Quản lý hồ sơ & văn bản PRO.

• Quản lý hồ sơ nhân sự bằng Google SheetsCột cần có, công thức và nhắc hạn hợp đồng lao động
• Cách khoá ô công thức trong Google SheetsChỉ cảnh báo, chặn hẳn, chừa ô nhập liệu
• Hướng dẫn cài đặt Quản lý hồ sơ & văn bản PROCài file, phân quyền, cổng xử lý trên điện thoại