Mẹo Google Sheets · 13 phút đọc
Muốn định dạng số tiền trong Google Sheets kiểu Việt Nam (2.500.000 ₫), đặt vùng của file là Việt Nam ở Tệp › Cài đặt, rồi gán định dạng số tùy chỉnh #,##0 "₫" cho cột tiền. Bài này giải thích vì sao số hay hiện 2,500,000, các mã định dạng chép dùng ngay (VND, triệu, tỷ, số âm màu đỏ), cách giữ số 0 ở đầu số điện thoại, khi nào phải ROUND thay vì chỉ ẩn số lẻ, hàm TEXT, đọc số thành chữ và cách làm tương đương trong Excel.
Hai bước là đủ cho phần lớn bảng tính tiền ở Việt Nam:
Điều quan trọng nhất cần nhớ: định dạng chỉ đổi cách hiển thị, không đổi giá trị. Ô hiện "2,5 tr" vẫn chứa 2.500.000 và SUM vẫn cộng đúng 2.500.000. Ngược lại, nếu ô chứa chữ "2.500.000đ" (gõ cả chữ đ vào ô) thì đó không còn là số nữa và không định dạng nào cứu được, phần cuối bài nói cách nhận ra.
Vì file đang để vùng Hoa Kỳ (mặc định của nhiều tài khoản). Cài đặt vùng của file quyết định dấu phân cách, dấu thập phân, kiểu ngày và cả dấu ngăn các đối số trong công thức:
| Vùng Hoa Kỳ | Vùng Việt Nam | |
|---|---|---|
| Hai triệu rưỡi | 2,500,000 | 2.500.000 |
| Số lẻ | 1,234.5 | 1.234,5 |
| Ngăn đối số trong công thức | =ROUND(A2, -3) | =ROUND(A2; -3) |
| Ngày 3 tháng 7 | 7/3/2026 | 03/07/2026 |
| Đơn vị của định dạng Tiền tệ | Đô la ($) | Đồng (₫) |
Đổi vùng ở Tệp › Cài đặt, mục Ngôn ngữ. Cài đặt này áp dụng cho cả file và mọi người cùng mở, còn ngôn ngữ giao diện của bạn thì không đổi. Công thức có sẵn trong file được Google tự chuyển dấu phẩy thành dấu chấm phẩy, bạn không phải sửa tay. Cách kiểm tra file đang để vùng nào và ảnh hưởng tới cột ngày có ở bài sửa lỗi ngày tháng.
Đổi vùng sau khi đã dán số
Số dán từ nơi khác vào file vùng Hoa Kỳ, kiểu "2.500.000", có thể bị hiểu thành chữ (không cộng được), còn "1.500" có thể bị hiểu thành một phẩy năm. Nên đặt vùng Việt Nam trước khi nhập dữ liệu. Cột đã lỡ thành chữ thì sửa theo bài SUM bằng 0.
Mở Định dạng › Số › Định dạng số tùy chỉnh, gõ mã vào ô rồi bấm Áp dụng. Mã dùng lại được: lần sau nó nằm sẵn trong danh sách.
Một điểm hay làm người dùng Việt bối rối: trong mã định dạng, dấu phẩy luôn là phân cách hàng nghìn và dấu chấm luôn là dấu thập phân, dù file để vùng nào. Google tự hiển thị ra dấu theo vùng. Vậy bạn gõ #,##0.00 và file vùng Việt Nam sẽ hiện 2.500.000,00. Đừng gõ #.##0 theo thói quen, mã đó sẽ hiểu dấu chấm là thập phân.
| Mã | 2500000 hiện thành | Dùng khi |
|---|---|---|
| #,##0 | 2.500.000 | Cột tiền thường, tiêu đề cột đã ghi "(đồng)" |
| #,##0 "₫" | 2.500.000 ₫ | Hoá đơn, báo giá |
| #,##0"đ" | 2.500.000đ | Bảng nội bộ, tin nhắn |
| #,##0.00 | 2.500.000,00 | Tiền ngoại tệ, đơn giá có số lẻ |
| "VND "#,##0 | VND 2.500.000 | Chứng từ gửi đối tác nước ngoài |
| #,##0;-#,##0;"-" | 2.500.000 (số 0 hiện "-") | Bảng kế toán, cho dễ nhìn ô trống |
Chữ thêm vào phải nằm trong ngoặc kép. Mã có tối đa 4 phần ngăn bằng dấu chấm phẩy theo thứ tự số dương; số âm; số 0; chữ. Chỉ ghi một phần thì phần đó dùng cho mọi số.
Nếu chỉ cần ký hiệu đồng mà không muốn nhớ mã, dùng Định dạng › Số › Tiền tệ: file vùng Việt Nam sẽ dùng đơn vị đồng. Muốn chọn đơn vị khác hoặc bỏ số lẻ, vào Đơn vị tiền tệ tùy chỉnh trong cùng menu.
Bảng tổng hợp, biểu đồ doanh thu dễ đọc hơn khi số ngắn lại. Mỗi dấu phẩy đặt sau các chữ số trong mã chia số hiển thị cho 1.000:
#,##0.0,, "tr"#,##0.00,,, "tỷ"#,##0, "k"Muốn một cột tự chọn đơn vị theo độ lớn, dùng điều kiện trong ngoặc vuông. Google chỉ cho đặt điều kiện ở hai phần đầu, phần thứ ba dùng cho mọi số còn lại:
[>=1000000000]#,##0.0,,," tỷ";[>=1000000]#,##0.0,," tr";#,##0Thử lại với 1.250.000.000: thoả điều kiện đầu, chia ba lần cho 1.000 được 1,25, mã chỉ có một chữ số lẻ nên hiện 1,3 tỷ. Cần chính xác hơn thì dùng .00 như mã ở trên. Lưu ý mã này dồn số âm vào phần thứ ba, nên -5.000.000 hiện -5.000.000 chứ không rút gọn.
Phần thứ hai của mã là cách hiện số âm. Thêm màu trong ngoặc vuông, tên màu phải viết bằng tiếng Anh:
#,##0;[Red]-#,##0#,##0 "₫";[Red](#,##0 "₫");"-"Màu dùng được gồm Black, White, Red, Blue, Green, Magenta, Yellow, Cyan và Color1 đến Color56. Muốn tô theo điều kiện phức tạp hơn (quá hạn, vượt ngân sách), dùng định dạng có điều kiện thay vì mã số.
Gõ 0912345678 vào ô thường, Google hiểu là số và bỏ số 0 vô nghĩa ở đầu, còn lại 912345678. Có ba cách giữ lại:
| Cách | Làm thế nào | Ghi chú |
|---|---|---|
| Định dạng văn bản | Chọn cột trước khi gõ, Định dạng › Số › Văn bản thuần tuý | Nên dùng cho số điện thoại, CCCD, số tài khoản |
| Dấu nháy đơn | Gõ '0912345678 | Dấu ' không hiện trong ô, ô thành chữ |
| Mã số 0 cố định | Định dạng số tùy chỉnh 0000000000 | Vẫn là số; hợp với mã độ dài cố định như 00125 |
Với số điện thoại, căn cước công dân (12 số), số tài khoản: hãy để văn bản thuần tuý. Những dãy này không bao giờ đem đi cộng trừ, và dãy quá 15 chữ số như số thẻ sẽ bị làm tròn nếu để dạng số. Đặt định dạng trước khi gõ hoặc dán; đổi định dạng sau khi số 0 đã mất thì không lấy lại được, phải gõ lại hoặc thêm bằng công thức =TEXT(A2; "0000000000") với số di động 10 chữ số.
Cột tiền thì ngược lại: không để văn bản thuần tuý, nếu không mọi số gõ vào đều thành chữ và SUM ra 0.
Bớt chữ số thập phân bằng định dạng (hoặc nút giảm số thập phân trên thanh công cụ) chỉ ẩn phần lẻ. Giá trị thật vẫn còn, và tổng cộng tính trên giá trị thật. Kết quả là những con số nhìn thấy cộng lại không khớp với dòng tổng.
Thử lại: =10000000/3 cho ra 3.333.333,33…; định dạng #,##0 hiện 3.333.333. Ba ô như vậy cộng lại vẫn ra 10.000.000, trong khi người đọc cộng tay ba số trên màn hình ra 9.999.999. Với tiền phải chuyển khoản, hãy làm tròn thật:
| Hàm | Ví dụ với 3.278.456 | Kết quả |
|---|---|---|
| ROUND (làm tròn thường) | =ROUND(A2; -3) | 3.278.000 |
| ROUNDUP (luôn lên) | =ROUNDUP(A2; -3) | 3.279.000 |
| ROUNDDOWN (luôn xuống) | =ROUNDDOWN(A2; -3) | 3.278.000 |
| MROUND (bội số gần nhất) | =MROUND(A2; 500) | 3.278.500 |
| ROUND về đồng | =ROUND(A2; 0) | 3.278.456 |
Đối số thứ hai âm nghĩa là làm tròn sang trái dấu thập phân: -3 là tới hàng nghìn, -2 là tới hàng trăm. Chia tiền theo nhóm theo kiểu trên có ví dụ đầy đủ ở bài cách chia tiền đi chơi nhóm; tiền điện nước phòng trọ làm tròn thế nào xem cách tính tiền điện nước phòng trọ.
Nối thẳng một ô tiền vào chữ thì định dạng biến mất: ="Tổng: "&B2 cho ra "Tổng: 2500000". Bọc TEXT với cùng mã định dạng để giữ dấu chấm:
="Tổng tiền: "&TEXT(B2; "#,##0")&" đồng"="Phòng "&A2&" còn nợ "&TEXT(C2; "#,##0")&"đ"Hay dùng nhất là để soạn tin nhắn nhắc tiền, dòng tóm tắt trên báo cáo, hay nội dung chuyển khoản. Kết quả của TEXT là chữ, nên chỉ dùng cho hiển thị; đừng đem cột TEXT đi cộng. Cách nối nhiều cột, bỏ ô trống khi nối có ở bài tách và gộp cột.
Nói thẳng: Google Sheets không có hàm đọc số thành chữ tiếng Việt, Excel cũng không. Định dạng số không làm được việc này. Cách thực tế là thêm một hàm tự viết bằng Apps Script rồi gõ =DOCSO(B2) như hàm thường; đoạn mã đã thử với các trường hợp "linh", "mốt", "lăm" nằm trong bài mẫu báo giá Excel, Google Sheets.
Nếu chưa dùng Apps Script bao giờ, đọc bài Apps Script là gì để biết cách mở trình soạn mã, cấp quyền và những gì cần kiểm tra trước khi dán một đoạn mã lạ. Hàm tự viết chỉ chạy trên Google Sheets; tải về .xlsx thì ô đó thành giá trị tĩnh.
Bạn chọn #,##0 mà cột vẫn hiện 2500000 hoặc "2.500.000đ" y nguyên, căn trái ô? Gần như chắc chắn ô đó đang chứa chữ, không phải số: gõ kèm chữ đ, dán từ web, hay cột bị đặt văn bản thuần tuý từ trước. Kiểm tra nhanh bằng =ISNUMBER(B2): ra FALSE là chữ.
Nguyên nhân và bốn cách đổi lại thành số đã có đủ trong bài sửa lỗi SUM bằng 0. Để khỏi lặp lại: chỉ gõ con số vào ô tiền, để định dạng lo phần dấu chấm và chữ đ.
Excel dùng cùng loại mã nhưng khác chỗ cài đặt:
So sánh rộng hơn giữa hai nền tảng có ở bài Google Sheets hay Excel.
Đặt vùng của file là Việt Nam ở Tệp › Cài đặt › Ngôn ngữ, rồi gán định dạng #,##0 cho cột. 2500000 sẽ hiện 2.500.000.
Định dạng › Số › Định dạng số tùy chỉnh, gõ #,##0"đ" (liền) hoặc #,##0 "₫" (có cách và ký hiệu đồng). Chỉ gõ con số vào ô, đừng gõ chữ đ vào ô.
Chọn cột, đặt Định dạng › Số › Văn bản thuần tuý trước khi gõ, hoặc gõ dấu nháy đơn trước số: '0912345678. Số đã mất số 0 thì phải gõ lại hoặc dùng =TEXT(A2; "0000000000").
Ô đó đang chứa chữ chứ không phải số (dán từ web, gõ kèm chữ đ, cột để văn bản thuần tuý). Kiểm tra bằng =ISNUMBER(B2) và đổi lại thành số theo bài sửa lỗi SUM bằng 0.
Dùng mã #,##0.0,, "tr". Mỗi dấu phẩy sau chữ số chia hiển thị cho 1.000, nên 2.500.000 hiện 2,5 tr. Giá trị thật trong ô không đổi.
Không có hàm có sẵn. Thêm hàm tự viết bằng Apps Script (ví dụ DOCSO) rồi dùng =DOCSO(B2); hàm chỉ chạy trên Google Sheets.
Mẫu khác liên quan: Bán hàng 360 PRO.
Google Sheets hay Excel: so chi phí, làm chung, dùng trên điện thoại, khi mất mạng, giới hạn dữ liệu, Apps Script với VBA và các công thức khác nhau.
Apps Script trong Google Sheets cho người mới: mở trình soạn, viết hàm đầu tiên, hàm tuỳ chỉnh, onEdit ghi giờ, trigger hằng ngày, gửi email, cấp quyền, quota.
Cách dùng hàm SUMIFS và COUNTIFS trong Google Sheets: cú pháp, nhiều điều kiện, lọc theo tháng bằng DATE, ký tự đại diện, sửa lỗi ra 0, so với SUMIF.
Cách dùng hàm XLOOKUP trong Google Sheets: gõ mã khách ra tên, SĐT, hạng; tra sang trái, giá trị khi không thấy, khớp gần đúng, sửa lỗi #N/A.
Xem thêm mẹo và video hướng dẫn trên kênh YouTube HiTaVa, hoặc đọc các bài khác trong chủ đề Mẹo Google Sheets.
Cần hỏi thêm?Zalo 0935077673 (Hải Vân)
