Cách tính lương net sang gross 2026: quy đổi ngược theo bậc thuế, có công thức Sheets

Chiều xuôi, tính lương gross sang net là trừ bảo hiểm 10,5% rồi trừ thuế luỹ tiến. Bảo hiểm là tỷ lệ cố định (tới trần), nhưng thuế thì không: mỗi đồng gross thêm vào có thể chịu 0%, 5%, 10%, 20%… tuỳ đang ở bậc nào. Vì vậy tỷ lệ net/gross thay đổi theo mức lương và theo số người phụ thuộc.

Sai thường gặp: lấy net 26.592.500đ chia 89,5% ra 29.712.291đ. Tính xuôi lại: bảo hiểm 3.119.790đ, thu nhập tính thuế 4.892.501đ, thuế 244.625đ, net chỉ còn 26.347.876đ — thiếu 244.624đ mỗi tháng, đúng bằng phần thuế bị bỏ quên. Chia 89,5% chỉ đúng khi người đó không phải nộp thuế.

Ý tưởng: với người dưới trần bảo hiểm, net = thu nhập tính thuế (TN) + giảm trừ − thuế. Đặt Q = net − giảm trừ gia cảnh, ta có Q = TN − thuế. Trong mỗi bậc, thuế = TN × thuế suất − số trừ nhanh, nên giải ngược được TN từ Q bằng một phép chia. Đây cũng là cách cơ quan thuế từng hướng dẫn quy đổi "thu nhập không bao gồm thuế" (Phụ lục 02/PL-TNCN Thông tư 111/2013) — bảng dưới dựng lại theo biểu 5 bậc và giảm trừ 2026.

1. Giảm trừ D = 15.500.000 + 6.200.000 × số người phụ thuộc. Q = net − D.
2. Q ≤ 0: không có thuế, gross = net ÷ 89,5%.
3. Q > 0: tra bảng để ra TN (thu nhập tính thuế).
4. Gross = (TN + D) ÷ 89,5% nếu kết quả không quá 50.600.000đ (trần BHXH, BHYT từ 07/2026).
5. Vượt trần: BHXH + BHYT cố định 8% × 50.600.000 + 1,5% × 50.600.000 = 4.807.000đ, BHTN vẫn 1% gross → gross = (TN + D + 4.807.000) ÷ 99%.
6. Vượt cả trần BHTN (vùng I 106.200.000đ): bảo hiểm cố định 5.869.000đ → gross = TN + D + 5.869.000.

Các trần và tỷ lệ bảo hiểm giải thích ở bài cách tính BHXH 2026; biểu thuế và giảm trừ ở bài cách tính thuế TNCN 2026. Doanh nghiệp ở vùng II–IV thay 106.200.000 bằng trần BHTN của vùng mình (94,6 / 82,8 / 74 triệu) và 5.869.000 bằng 4.807.000 + 1% trần đó.

Net 13.425.000đ, không người phụ thuộc. Q = 13.425.000 − 15.500.000 = âm → không thuế. Gross = 13.425.000 ÷ 89,5% = 15.000.000đ.

Net 26.592.500đ, 1 người phụ thuộc. D = 21.700.000, Q = 4.892.500 → bậc 1: TN = 4.892.500 ÷ 95% = 5.150.000. Gross = (5.150.000 + 21.700.000) ÷ 89,5% = 26.850.000 ÷ 89,5% = 30.000.000đ.

Net 50.274.400đ, không người phụ thuộc. Q = 34.774.400 → bậc 3: TN = (34.774.400 − 3.500.000) ÷ 80% = 39.093.000. Thử (TN + D) ÷ 89,5% = 60.997.765 — vượt 50,6 triệu, nên dùng công thức trên trần: (39.093.000 + 15.500.000 + 4.807.000) ÷ 99% = 59.400.000 ÷ 99% = 60.000.000đ.

B2 là lương net muốn nhận, B3 số người phụ thuộc. Công thức một ô dưới đây làm đúng các bước ở bảng quy đổi, dùng LET (có trong Google Sheets và Excel 365):

=LET(net; B2; d; 15500000 + B3*6200000; q; net - d; tn; IF(q<=0; q; IFS(q<=9500000; q/95%; q<=27500000; (q-500000)/90%; q<=51500000; (q-3500000)/80%; q<=79500000; (q-9500000)/70%; TRUE; (q-14500000)/65%)); g1; (tn + d)/89,5%; g2; (tn + d + 4807000)/99%; ROUNDUP(IF(g1<=50600000; g1; IF(g2<=106200000; g2; tn + d + 5869000)); 0))

Đừng tin ngay con số quy đổi — kiểm bằng cách tính xuôi về net rồi so với B2. Ô D2 dưới đây tính net từ gross ở C2 (cùng công thức với bài gross sang net) và trừ đi net mong muốn:

=LET(g; C2; bh; ROUND(MIN(g; 50600000)*8%; 0) + ROUND(MIN(g; 50600000)*1,5%; 0) + ROUND(MIN(g; 106200000)*1%; 0); tn; MAX(0; g - bh - 15500000 - B3*6200000); thue; ROUND(SUMPRODUCT((tn>{0;10;30;60;100}*10^6) * (tn-{0;10;30;60;100}*10^6) * {5;5;10;10;5}/100); 0); g - bh - thue - B2)

Hai công thức gõ cứng trần 50.600.000 (BHXH, BHYT từ 07/2026) và 106.200.000 (BHTN vùng I). File dùng nhiều kỳ nên để các số này trong bảng tham số có ngày hiệu lực, như hướng dẫn ở bài cách tính lương nhân viên bằng Excel. Máy để vùng Hoa Kỳ thì đổi ; thành dấu phẩy và 89,5% thành 89.5%.

Khi gross có nhiều phần (phụ cấp không đóng bảo hiểm, khoản miễn thuế) thì công thức đảo phức tạp hơn nhiều. Lúc đó cách chắc ăn là để một ô tính xuôi gross → net, rồi cho máy dò gross.

• Excel: dùng Goal Seek (trong nhóm What-If Analysis của thẻ Data): ô đích là ô net tính xuôi, giá trị cần đạt là net mong muốn, ô thay đổi là ô gross. Excel dò trong vài giây.
• Google Sheets: không có Goal Seek dựng sẵn như Excel; có thể cài tiện ích bổ sung cùng tên từ Google Workspace Marketplace, hoặc thử dần bằng tay như dưới.

Thử dần bằng tay (net 26.592.500đ, 1 người phụ thuộc): đoán gross = net ÷ 89,5% = 29.712.291 → tính xuôi ra 26.347.876, thiếu 244.624. Mỗi đồng gross thêm vào chỉ tăng net khoảng 89,5% × (100% − 5%) = 0,85 đồng (đang ở bậc 5%), nên cộng thêm 244.624 ÷ 0,85025 ≈ 287.708 → gross 29.999.999 → net 26.592.499, thiếu 1đ → gross 30.000.000. Thường chỉ cần hai lần thử.

Trả lương net nghĩa là công ty cam kết số thực nhận và chịu phần bảo hiểm, thuế thay người lao động. Phần thuế công ty trả thay cũng là thu nhập chịu thuế — vì vậy kế toán luôn phải quy đổi ra gross để khai thuế và đóng bảo hiểm. Khi luật hoặc hoàn cảnh thay đổi, gross phải đổi theo, và hợp đồng cần nói rõ ai hưởng, ai chịu.

• Trần bảo hiểm tăng: để giữ net 50.274.400đ (không người phụ thuộc), gross cần 59.635.354đ khi trần là 46,8 triệu nhưng phải lên 60.000.000đ từ kỳ 07/2026 — công ty chịu thêm khoảng 364.646đ gross mỗi tháng, chưa kể phần bảo hiểm doanh nghiệp đóng tăng theo.
• Thuế giảm: giữ net 26.592.500đ (1 người phụ thuộc), theo giảm trừ và biểu 7 bậc năm 2025 cần gross khoảng 30.933.289đ; với giảm trừ và biểu 2026 chỉ cần 30.000.000đ. Nếu hợp đồng chỉ ghi net, khoản giảm này về phía công ty.
• Thay đổi người phụ thuộc: người lao động đăng ký thêm con thì gross cần thấp hơn. Ghi rõ net được tính với bao nhiêu người phụ thuộc và khi đổi thì xử lý ra sao.
• Quyết toán và thu nhập nơi khác: công ty thường chỉ cam kết net trên phần lương mình trả. Người có thu nhập ở nơi khác phải tự quyết toán và có thể nộp thêm — nên ghi rõ phần thuế phát sinh này ai chịu, và khoản hoàn thuế cuối năm (ví dụ do tháng 1–6/2026 đã tạm khấu trừ theo biểu cũ) thuộc về ai.
• Ghi cả gross: hồ sơ BHXH và tờ khai thuế dùng con số gross, nên nhiều công ty ghi gross đã quy đổi trong hợp đồng hoặc phụ lục, kèm câu "thực nhận không thấp hơn … theo quy định tại thời điểm ký".

1. 

   Tính lương 2026 trên Google Sheets: chấm công, tăng ca, BHXH, thuế TNCN

   Xem trên YouTube ↗

• Cách tính lương gross sang netChiều xuôi, bảng tra nhanh nhiều mức lương
• Lương gross và net là gìNên thoả thuận lương gross hay net
• Mức lương tối thiểu vùng 2026Sàn lương và trần BHTN theo vùng
• Cách tính lương nhân viên bằng Excel9 bước từ chấm công tới thực nhận