Cách tính lương gross sang net 2026: công thức, ví dụ và bảng tính nhanh

Lương gross là tổng lương trước khi trừ bảo hiểm và thuế — con số thường ghi trong hợp đồng lao động. Lương net là số tiền thực nhận về tài khoản. Khác nhau giữa hai số chỉ gồm hai khoản bắt buộc của người lao động: bảo hiểm và thuế thu nhập cá nhân. Nếu bạn chưa rõ hai khái niệm này, đọc trước bài lương gross và net là gì.

Lương net = Lương gross − (BHXH 8% + BHYT 1,5% + BHTN 1%) − Thuế TNCN

Bảo hiểm người lao động

10,5% lương đóng BH

Trần BHXH, BHYT từ 01/07/2026

50.600.000đ

Giảm trừ bản thân

15.500.000đ/tháng

Mỗi người phụ thuộc

6.200.000đ/tháng

1. Bảo hiểm = 8% × MIN(lương đóng BH; trần BHXH) + 1,5% × MIN(lương đóng BH; trần BHXH) + 1% × MIN(lương đóng BH; trần BHTN).
2. Thu nhập tính thuế = gross − khoản miễn thuế − bảo hiểm − 15.500.000 − 6.200.000 × số người phụ thuộc. Âm thì lấy 0.
3. Thuế TNCN = áp biểu luỹ tiến 5 bậc lên thu nhập tính thuế.
4. Lương net = gross − bảo hiểm − thuế.

Giảm trừ gia cảnh không bị trừ vào lương: nó chỉ làm nhỏ phần thu nhập bị tính thuế. Đây là chỗ nhiều người tính nhầm khi lần đầu đổi lương gross sang net.

Hai điều cần nhớ khi tính lương gross net: thứ nhất, lương đóng bảo hiểm là mức lương, phụ cấp lương và khoản bổ sung trả thường xuyên ghi trong hợp đồng — không nhất thiết bằng cả lương gross nếu gross có khoản thưởng hay hỗ trợ không thường xuyên. Thứ hai, với người làm đủ giờ, lương này không được thấp hơn lương tối thiểu vùng (vùng I 5.310.000đ). Chi tiết ở bài cách tính BHXH 2026 và mức lương tối thiểu vùng 2026.

Nghị quyết 110/2025/UBTVQH15 nâng giảm trừ gia cảnh lên 15,5 triệu đồng/tháng cho bản thân và 6,2 triệu đồng/tháng cho mỗi người phụ thuộc đã đăng ký, áp dụng từ kỳ tính thuế 2026. Luật Thuế TNCN 109/2025/QH15 có hiệu lực từ 01/07/2026, nhưng phần tiền lương, tiền công của cá nhân cư trú áp dụng cho cả kỳ tính thuế 2026 với biểu 5 bậc:

Với người có toàn bộ gross là lương đóng bảo hiểm và không có khoản miễn thuế, mức gross bắt đầu phải nộp thuế năm 2026 là khoảng 17,32 triệu (không người phụ thuộc), 24,25 triệu (1 người) và 31,17 triệu (2 người). Cách tính thuế đầy đủ, kể cả người không cư trú và hợp đồng dưới 3 tháng, ở bài cách tính thuế TNCN 2026.

Cả ba ví dụ giả định: kỳ lương 10/2026, doanh nghiệp ở vùng I, toàn bộ gross là lương đóng bảo hiểm và chịu thuế, cá nhân cư trú, chỉ có một nơi trả lương.

Ví dụ 1 — gross 15.000.000đ, không người phụ thuộc. Bảo hiểm = 1.200.000 + 225.000 + 150.000 = 1.575.000đ. Thu nhập tính thuế = 15.000.000 − 1.575.000 − 15.500.000 = âm, lấy 0 → thuế 0đ. Lương net 13.425.000đ.

Ví dụ 2 — gross 30.000.000đ, 1 người phụ thuộc. Bảo hiểm = 2.400.000 + 450.000 + 300.000 = 3.150.000đ. Giảm trừ = 15.500.000 + 6.200.000 = 21.700.000đ. Thu nhập tính thuế = 30.000.000 − 3.150.000 − 21.700.000 = 5.150.000đ, bậc 1 → thuế 5.150.000 × 5% = 257.500đ. Lương net 26.592.500đ.

Ví dụ 3 — gross 60.000.000đ, không người phụ thuộc (chạm trần). BHXH và BHYT chỉ tính trên 50.600.000đ, còn BHTN tính trên đủ 60 triệu vì dưới trần BHTN vùng I:

Cùng gross 60 triệu nhưng ở kỳ 06/2026 (trần cũ 46,8 triệu): bảo hiểm 5.046.000đ, thu nhập tính thuế 39.454.000đ, thuế 4.390.800đ, net 50.563.200đ — cao hơn kỳ 10/2026 là 288.800đ. Một số nơi đã tạm khấu trừ tháng 1–6/2026 theo biểu 7 bậc cũ; phần chênh được tính lại khi quyết toán thuế năm 2026.

Đọc bảng: dưới khoảng 17 triệu, net luôn bằng 89,5% gross vì chưa có thuế. Từ đó trở lên, tỷ lệ net/gross giảm dần — 30 triệu còn 87,4% (không người phụ thuộc), 100 triệu còn 80,1%. Vì vậy không thể đổi lương gross sang net bằng một tỷ lệ cố định cho mọi mức lương; chiều ngược lại cũng vậy, xem cách tính lương net sang gross.

Đặt mỗi nhân viên một dòng: B5 lương gross (coi là lương đóng BH), C5 số người phụ thuộc. Bốn cột sau tính lần lượt bảo hiểm, thu nhập tính thuế, thuế và lương net. Các số 50600000 (trần BHXH từ 07/2026) và 106200000 (trần BHTN vùng I) nên để trong một ô tham số thay vì gõ cứng.

=ROUND(MIN(B5; 50600000)*8%; 0) + ROUND(MIN(B5; 50600000)*1,5%; 0) + ROUND(MIN(B5; 106200000)*1%; 0)

=MAX(0; B5 - D5 - 15500000 - C5*6200000)

=ROUND(IFS(E5<=10000000; E5*5%; E5<=30000000; E5*10%-500000; E5<=60000000; E5*20%-3500000; E5<=100000000; E5*30%-9500000; TRUE; E5*35%-14500000); 0)

=B5 - D5 - F5

Muốn gọn trong một ô (B2 gross, B3 số người phụ thuộc), dùng LET — có trong Google Sheets và Excel 365:

=LET(g; B2; bh; ROUND(MIN(g; 50600000)*8%; 0) + ROUND(MIN(g; 50600000)*1,5%; 0) + ROUND(MIN(g; 106200000)*1%; 0); tn; MAX(0; g - bh - 15500000 - B3*6200000); thue; ROUND(SUMPRODUCT((tn>{0;10;30;60;100}*10^6) * (tn-{0;10;30;60;100}*10^6) * {5;5;10;10;5}/100); 0); g - bh - thue)

Nếu muốn tự dựng file, bài cách tính lương nhân viên bằng Excel đi qua đủ 9 bước và cách tra tham số theo kỳ lương.

• Phụ cấp không đóng bảo hiểm: khoản hỗ trợ không thường xuyên nằm trong gross nhưng không vào lương đóng BH — bảo hiểm nhỏ hơn 10,5% gross.
• Khoản miễn thuế: tiền làm thêm giờ đủ điều kiện, phụ cấp ăn trong mức hướng dẫn… được trừ trước khi tính thuế. Mức cụ thể nên hỏi kế toán.
• Ngày công: nghỉ không lương làm giảm lương theo ngày công nhưng lương đóng BH vẫn theo hợp đồng; nghỉ không lương từ 14 ngày làm việc trở lên trong tháng thì tháng đó không đóng BHXH.
• Đoàn phí công đoàn (nếu là đoàn viên), tạm ứng, khấu trừ khác cũng làm số chuyển khoản nhỏ hơn net theo công thức.
• Người không cư trú chịu 20% trên thu nhập chịu thuế, không giảm trừ gia cảnh. Hợp đồng dưới 3 tháng thường bị khấu trừ 10% khi mỗi lần trả từ ngưỡng luật định — không dùng biểu luỹ tiến.

• Cách tính lương net sang grossQuy đổi ngược theo từng bậc thuế, cùng bộ số
• Lương gross và net là gìKhác nhau thế nào, nên thoả thuận loại nào
• Cách tính thuế TNCN 2026Biểu 5 bậc, giảm trừ, trường hợp đặc biệt
• Cách tính BHXH 2026Tỷ lệ đóng, trần BHXH và BHTN theo vùng