Lớp học & trung tâm · 16 phút đọc
Quản lý học viên trung tâm tiếng Anh nhỏ gói gọn trong hai bảng: bảng Học viên (mỗi người một dòng, có điểm test và trình độ) và bảng Khoá học (mỗi lần đăng ký khoá một dòng, có số buổi còn và ngày dự kiến hết). Từ hai bảng đó, vài công thức Google Sheets tự xếp trình độ theo điểm test, báo học viên sắp hết khoá hoặc nghỉ nhiều, và tính tỷ lệ gia hạn, tỷ lệ giữ chân mỗi tháng. Bài này đi qua từng cột, từng công thức có ví dụ số, và cách dùng các con số đó để giữ học viên ở lại.
Trung tâm 50–300 học viên thường rối không phải vì thiếu dữ liệu mà vì dữ liệu nằm rải rác: điểm test trong tin nhắn Zalo, ngày bắt đầu khoá trong sổ giáo vụ, học phí trong sổ thu. Tới lúc cần biết "tháng này ai hết khoá để gọi gia hạn" thì phải lật ba chỗ.
Nguyên tắc quan trọng nhất: tách người khỏi khoá học. Một học viên học Level 2 rồi Level 3, rồi nghỉ hè, rồi quay lại luyện thi — đó là một dòng ở bảng Học viên và bốn dòng ở bảng Khoá học. Nếu gộp chung, bạn sẽ phải ghi đè khoá cũ và mất luôn lịch sử để tính tỷ lệ gia hạn.
| Bảng | Mỗi dòng là | Cột chính |
|---|---|---|
| Học viên | Một người | Mã HV, họ tên, ngày sinh, phụ huynh, SĐT, nguồn, điểm test, trình độ, ngày nhập học, ngày nghỉ, lý do nghỉ |
| Khoá học | Một lần đăng ký khoá | Mã HV, lớp, khoá, ngày bắt đầu, số buổi gói, đã học, còn lại, dự kiến hết, trạng thái, gia hạn |
| Điểm danh | Một buổi của một học viên | Ngày, mã HV, lớp, ký hiệu C / M / P / V |
| Thang xếp lớp | Một mức điểm | Điểm từ, level, CEFR tương ứng |
Điểm danh và thời khoá biểu đã có bài riêng: cách điểm danh học sinh bằng Google Sheets và cách xếp thời khoá biểu trung tâm. Bài này chỉ dùng kết quả của chúng.
Ghi đủ để liên lạc, xếp lớp và chăm sóc; đừng ghi thứ bạn không dùng. Với học viên nhỏ tuổi, người liên lạc và người trả tiền là phụ huynh, nên tách cột phụ huynh ra khỏi cột học viên.
| Cột | Ví dụ | Dùng để |
|---|---|---|
| A · Mã HV | HV0128 | Khoá chính, nối mọi bảng. Không dùng họ tên làm mã vì trùng tên rất hay gặp |
| B · Họ tên | Nguyễn Minh Anh | Hiển thị |
| C · Ngày sinh | 12/03/2014 | Chia nhóm tuổi (Kids, Teens, người lớn), chúc sinh nhật |
| D, E · Phụ huynh, SĐT | Chị Hương · 09xx | Gọi tư vấn gia hạn, báo nghỉ |
| F · Nguồn | Facebook, người quen giới thiệu | Biết kênh nào mang về học viên ở lâu |
| G, H · Điểm test, điểm nói | 62 · 6 | Xếp lớp, so tiến bộ |
| I · Trình độ | Level 3 | Công thức tự tính từ G |
| J · Ngày nhập học | 08/09/2025 | Tính tỷ lệ giữ chân |
| K, L · Ngày nghỉ, lý do | 15/08/2026 · Chuyển nhà | Biết vì sao học viên rời đi |
| M · Đồng ý dữ liệu | Có (ngày ký) | Lưu bằng chứng phụ huynh đã đồng ý |
Cột Nguồn và Lý do nghỉ nên là danh sách thả xuống thay vì gõ tự do, để đếm được — cách làm ở bài tạo danh sách thả xuống trong Google Sheets. Gợi ý lý do nghỉ: Học phí, Lịch học không hợp, Chuyển nhà, Không thấy tiến bộ, Chuyển trung tâm khác, Hết nhu cầu (đã thi xong), Khác.
Dữ liệu cá nhân của học viên
Luật Bảo vệ dữ liệu cá nhân (91/2025/QH15) có hiệu lực từ 01/01/2026 và có quy định riêng cho dữ liệu trẻ em. Trung tâm nên có phiếu đăng ký ghi rõ thu thông tin gì, dùng làm gì, có phụ huynh ký đồng ý; chỉ chia sẻ file cho người cần dùng. Chi tiết nghĩa vụ cụ thể nên hỏi luật sư.
Bài test đầu vào của trung tâm nhỏ thường gồm phần viết (ngữ pháp, từ vựng, đọc) chấm trên 100 và một buổi nói ngắn 5–10 phút chấm trên 10. Bạn cần một thang xếp lớp cố định để hai giáo viên chấm cùng một em ra cùng một lớp.
| A · Điểm từ | B · Level | C · Tương đương CEFR (tham khảo) |
|---|---|---|
| 0 | Level 1 | Pre-A1 |
| 30 | Level 2 | A1 |
| 50 | Level 3 | A2 |
| 70 | Level 4 | B1 |
| 85 | Level 5 | B2 |
=IF(G2="";"";XLOOKUP(G2;'Thang xếp lớp'!$A$2:$A$6;'Thang xếp lớp'!$B$2:$B$6;"";-1))Thử lại: G2 = 62 → không có mốc 62, mốc nhỏ hơn gần nhất là 50 → Level 3. G2 = 85 → khớp đúng mốc 85 → Level 5. G2 = 29 → mốc 0 → Level 1. Cột A phải xếp tăng dần. Cách dùng XLOOKUP kỹ hơn ở bài hàm XLOOKUP trong Google Sheets.
Em nằm sát mốc là ca khó nhất: 52 điểm vào Level 3 nhưng có thể theo không nổi. Thêm một cột báo sát ngưỡng để giáo viên quyết theo phần nói:
=IF(G2="";"";IF(ARRAYFORMULA(MIN(ABS(G2-{30;50;70;85})))<=3;"Sát ngưỡng — xem điểm nói";""))Thử lại: 62 → khoảng cách tới các mốc là 32, 12, 8, 23 → nhỏ nhất 8 → không báo. 52 → khoảng cách tới 50 là 2 → Sát ngưỡng. Quy tắc gợi ý: sát ngưỡng mà điểm nói từ 6 trở lên thì xếp lớp trên, dưới 6 thì xếp lớp dưới. Ghi quy tắc này thành chữ trong file để giáo vụ mới cũng làm giống nhau.
Trung tâm tiếng Anh hay bán theo khoá có số buổi cố định (24 buổi, 36 buổi) hơn là theo tháng. Bảng Khoá học, mỗi lần đăng ký một dòng: A Mã ĐK, B Học viên (mã HV, khớp với tab Điểm danh), C Lớp, D Khoá, E Ngày bắt đầu, F Số buổi gói, G Đã học, H Còn lại, I Dự kiến hết, J Vắng 4 tuần, K Trạng thái, L Ngày kết thúc thực tế, M Gia hạn (hộp kiểm).
=COUNTIFS('Điểm danh'!B:B;B2;'Điểm danh'!C:C;C2;'Điểm danh'!A:A;">="&E2;'Điểm danh'!D:D;"<>P")=F2-G2=IF(H2<=0;"";WORKDAY.INTL(TODAY();H2;"0101011";NgayNghi))Thử lại với hôm nay là thứ Bảy 24/10/2026, lớp thứ 2-4-6:
| Học viên | Gói | Đã học | Còn (H) | Dự kiến hết (I) |
|---|---|---|---|---|
| Nguyễn Minh Anh | 24 | 22 | 2 | Thứ Hai 26/10, thứ Tư 28/10 → 28/10/2026 |
| Lê Gia Huy | 36 | 30 | 6 | 06/11/2026 (thứ Sáu) |
| Trần Bảo Châu | 24 | 12 | 12 | 20/11/2026 |
| Đỗ Khánh Linh | 36 | 8 | 28 | 28/12/2026 |
Lớp học thứ 3-5-7 thì đổi chuỗi thành "1010101". Nếu hôm nay lớp có học mà chưa điểm danh, buổi hôm nay chưa bị trừ nên ngày dự kiến có thể sớm hơn thực tế một buổi — chấp nhận được vì đây là con số để nhắc việc, không phải để tính tiền.
Bảo lưu khoá
Học viên xin bảo lưu (ốm, đi du lịch, ôn thi ở trường) thì đừng xoá dòng khoá. Ghi trạng thái Bảo lưu và ngày quay lại; công thức trạng thái nên bỏ qua các dòng đang bảo lưu, nếu không học viên đó sẽ hiện "Nghỉ nhiều" suốt thời gian vắng.
Hai tình huống cần gọi điện sớm: sắp hết khoá (để tư vấn gia hạn trước khi phụ huynh tự tìm trung tâm khác) và nghỉ nhiều (dấu hiệu sắp bỏ học). Gọi khi còn 2 tuần thì phụ huynh còn thời gian sắp xếp tiền; gọi vào buổi cuối thì thường nghe câu "để chị tính đã".
=COUNTIFS('Điểm danh'!B:B;B2;'Điểm danh'!A:A;">"&TODAY()-28;'Điểm danh'!D:D;"V")+COUNTIFS('Điểm danh'!B:B;B2;'Điểm danh'!A:A;">"&TODAY()-28;'Điểm danh'!D:D;"P")=IF(H2<=0;"Hết khoá";IF(J2>=3;"Nghỉ nhiều";IF(OR(H2<=4;I2-TODAY()<=14);"Sắp hết khoá";"Đang học")))Thử lại: Minh Anh H2 = 2 ≤ 4 → Sắp hết khoá. Gia Huy còn 6 buổi (> 4) nhưng 06/11 − 24/10 = 13 ngày ≤ 14 → Sắp hết khoá. Bảo Châu còn 12 buổi nhưng J2 = 3 → Nghỉ nhiều. Thu Hà H2 = 0 → Hết khoá. Khánh Linh còn 28 buổi, 65 ngày → Đang học.
Lớp 3 buổi/tuần thì 28 ngày có khoảng 12 buổi; vắng 3 là vắng một phần tư. Lớp 2 buổi/tuần nên hạ ngưỡng xuống 2. Muốn bắt cả kiểu nghỉ hai buổi liền, dùng công thức ở bài điểm danh. Để cả dòng đổi màu: chọn vùng A2:M500 › Định dạng có điều kiện › công thức tuỳ chỉnh =$K2="Sắp hết khoá" tô vàng, =$K2="Nghỉ nhiều" tô đỏ nhạt.
=FILTER(B2:I500;(K2:K500="Sắp hết khoá")+(K2:K500="Nghỉ nhiều"))Tư vấn gia hạn hiệu quả nhất khi có số liệu của chính học viên đó: điểm test đầu khoá và cuối khoá, chuyên cần, nhận xét của giáo viên. "Con lên từ 62 lên 74 điểm, đủ vào Level 4" thuyết phục hơn mọi lời mời. Cách soạn nhận xét và phiếu gửi phụ huynh có ở bài báo cáo học tập cho phụ huynh.
Ưu đãi gia hạn sớm, ví dụ giảm 5% khi đóng trước ngày hết khoá ít nhất 7 ngày (GiaKhoa là học phí khoá mới, NgayDong là ngày phụ huynh đóng, I2 là ngày dự kiến hết khoá cũ):
=ROUND(GiaKhoa*(1-IF(NgayDong<=I2-7;5%;0));-3)Thử lại: khoá Level 4 giá 4.800.000đ, khoá cũ dự kiến hết 06/11/2026, phụ huynh đóng 28/10 → 28/10 ≤ 30/10 → giảm 5% → 4.560.000đ. Đóng ngày 02/11 → không giảm, 4.800.000đ. Các cách thu học phí khác (theo tháng, theo buổi, gói buổi, bảo lưu buổi nghỉ) có ở bài quản lý lớp dạy thêm bằng Google Sheets.
Khi học viên gia hạn: đánh dấu hộp kiểm ở cột M của dòng khoá cũ, ghi ngày kết thúc thực tế ở cột L, rồi thêm một dòng mới cho khoá mới. Đừng sửa số buổi của dòng cũ thành 48 — bạn sẽ mất dấu lần gia hạn này.
Hai con số nên xem mỗi tháng. Tỷ lệ gia hạn đo trong số học viên hết khoá, bao nhiêu người học tiếp. Tỷ lệ giữ chân đo trong số học viên có từ đầu tháng, bao nhiêu người còn ở cuối tháng — không tính học viên mới, để tuyển sinh tốt không che mất việc học viên cũ bỏ đi.
Ở bảng Học viên (J ngày nhập học, K ngày nghỉ — trống nếu còn học), ô O2 là ngày đầu kỳ 01/09/2026, O3 là ngày cuối kỳ 30/09/2026:
=COUNTIFS(J2:J2000;"<"&O2;K2:K2000;"")+COUNTIFS(J2:J2000;"<"&O2;K2:K2000;">="&O2)=COUNTIFS(J2:J2000;"<="&O3;K2:K2000;"")+COUNTIFS(J2:J2000;"<="&O3;K2:K2000;">"&O3)=COUNTIFS(J2:J2000;">="&O2;J2:J2000;"<="&O3)=(CuoiKy-MoiTrongKy)/DauKy=COUNTIFS('Khoá học'!L2:L2000;">="&O2;'Khoá học'!L2:L2000;"<="&O3;'Khoá học'!M2:M2000;TRUE)/COUNTIFS('Khoá học'!L2:L2000;">="&O2;'Khoá học'!L2:L2000;"<="&O3)Thử lại: đầu tháng 120, mới 15, nghỉ 11 → cuối tháng 124. Giữ chân = (124 − 15) ÷ 120 = 109 ÷ 120 = 90,8%, tức 9,2% học viên cũ rời đi trong tháng. Có 18 khoá kết thúc trong tháng 9, 13 dòng đã đánh dấu gia hạn → 72%. Học viên mới vào rồi nghỉ ngay trong cùng tháng không nằm trong cả hai số; nếu trung tâm hay gặp trường hợp này, đếm riêng nó như chỉ số "bỏ sau buổi học thử".
Mấy cách đọc số cho đúng:
Tự dựng hai bảng trên mất một buổi tối và chạy tốt cho trung tâm vài chục học viên. Khi thêm học phí, công nợ, lương giáo viên, nhiều lớp nhiều cơ sở, file tự làm bắt đầu khó giữ đúng. Mẫu Quản lý lớp học PRO có sẵn các phần này trong một file 29 tab:
Mẫu không có tab "test đầu vào" riêng: thang xếp lớp và cột sát ngưỡng ở trên bạn tự thêm nếu cần. Menu, mở kỳ tự động, phiếu học phí có mã QR và Web App cho giáo viên, phụ huynh chỉ chạy trên Google Sheets; mở bằng Excel vẫn dùng được mọi công thức. Từng bước cài đặt ở hướng dẫn Quản lý lớp học PRO.
Hướng dẫn cài đặt và sử dụng Quản lý lớp học PRO
Xem trên YouTube ↗Dưới khoảng 300 học viên, một hoặc hai người làm giáo vụ, Google Sheets đủ dùng: nhiều người mở cùng lúc, có lịch sử sửa, miễn phí. Khi cần ứng dụng riêng cho phụ huynh, thanh toán tự động qua cổng hay hàng chục cơ sở, phần mềm thuê bao hợp hơn. So sánh chi tiết ở bài Google Sheets hay Excel.
Khoảng 2 tuần hoặc khi còn 4 buổi, tuỳ cái nào tới trước. Ít hơn thì phụ huynh không kịp sắp xếp tiền và lịch; sớm hơn thì chưa có kết quả học tập để tư vấn.
Không có con số chuẩn chung cho mọi trung tâm, vì phụ thuộc độ tuổi, loại khoá (giao tiếp dài hạn hay luyện thi ngắn hạn) và mùa. Cách dùng đúng là so trung tâm mình theo thời gian và giữa các lớp với nhau, rồi đọc lý do nghỉ để biết cần sửa gì.
Có trong công thức, nhưng nên ghi lý do "Hết nhu cầu (đã thi xong)" để tách khỏi các lý do do trung tâm. Khi phân tích, bạn có thể tính thêm tỷ lệ gia hạn chỉ cho khoá giao tiếp dài hạn.
Nên làm, bằng cùng bài hoặc bài cùng độ khó. Chênh lệch điểm là bằng chứng tiến bộ rõ nhất khi tư vấn gia hạn, và giúp xếp lớp kế tiếp đúng trình độ.
Dùng tên level riêng cho lớp (Level 1–5, Kids 1–3) và ghi CEFR tương ứng làm tham khảo. Bài test của trung tâm nhỏ thường chưa được chuẩn hoá để khẳng định chính xác một bậc CEFR, nên đừng hứa với phụ huynh "đạt B1" chỉ dựa vào bài test nội bộ.
Cách quản lý lớp dạy thêm bằng Google Sheets: bảng điểm danh, 4 cách tính học phí, nghỉ có phép, học bù, phiếu có mã QR, công nợ và lương giáo viên.
Cách xếp thời khoá biểu cho trung tâm, lớp dạy thêm: dữ liệu lớp, phòng, giờ rảnh giáo viên, lưới tuần theo ca, COUNTIFS báo trùng phòng, trùng giáo viên.
Cách làm báo cáo học tập gửi phụ huynh cho lớp dạy thêm, trung tâm: nội dung cần có, tần suất, mẫu nhận xét cụ thể, công thức TEXTJOIN ghép tin Zalo.
Cách tính điểm trung bình môn học kỳ và cả năm THCS, THPT theo Thông tư 22: hệ số 1-2-3, làm tròn, xếp loại Tốt/Khá/Đạt, công thức Google Sheets có ví dụ.
Xem thêm mẹo và video hướng dẫn trên kênh YouTube HiTaVa, hoặc đọc các bài khác trong chủ đề Lớp học & trung tâm.
Cần hỏi thêm?Zalo 0935077673 (Hải Vân)
