Cách lên kế hoạch du lịch nhóm bằng Google Sheets: lịch trình, checklist, dự trù và quỹ chung

Chuyến đi nhóm hay rối ở bốn chỗ: không ai nắm lịch, quên đồ chung, không biết mỗi người cần chuẩn bị bao nhiêu tiền, và việc dồn hết lên một người. Mỗi chỗ một trang tính:

Ví dụ trong bài

6 người, Đà Lạt 13–15/11/2026

Tổng dự trù + 10% dự phòng

14.850.000đ

Dự trù mỗi người

2.480.000đ

Góp trước mỗi người

1.200.000đ

Tạo file, chia sẻ quyền chỉnh sửa cho cả nhóm, ghim link lên nhóm chat. Một người làm "trưởng đoàn" giữ cấu trúc file; người khác chỉ điền vào cột của mình. Phần chia tiền sau chuyến (ai nợ ai, ít lần chuyển khoản nhất) là chuyện riêng, đã có ở bài cách chia tiền đi chơi nhóm — bài này lo phần trước chuyến.

Mỗi hoạt động một dòng, sắp theo ngày rồi theo giờ. Đừng gộp "Ngày 2: săn mây, ăn sáng, đi chợ" vào một ô — tách dòng thì mới ghi được giờ, người lo và chi phí của từng việc.

Ô J1 ghi ngày đi (13/11/2026). Hai công thức tiện dụng: nhãn "Ngày mấy của chuyến" cho từng dòng, và số ngày còn lại tới hôm đi để nhắc cả nhóm.

=IF(A2=""; ""; "Ngày " & (A2 - $J$1 + 1))

=$J$1 - TODAY()

Thử lại: A2 = 14/11/2026, J1 = 13/11/2026 → 14/11 − 13/11 + 1 = 2 → "Ngày 2". Hôm nay 19/10/2026 thì ô đếm ngược ra 25. Nếu ô đếm ngược hiện thành ngày kiểu 25/01/1900 thì đổi định dạng ô sang Số. Ngày gõ bị hiểu thành tháng/ngày thì xem sửa lỗi ngày tháng trong Google Sheets.

• Ghi giờ cứng (giờ xe chạy, giờ nhận/trả phòng) trước, các hoạt động khác xếp vào khoảng trống.
• Mỗi ngày chừa ít nhất một khoảng trống 2–3 tiếng: đi nhóm luôn chậm hơn dự tính.
• Cột Ghi chú dán link bản đồ, số điện thoại homestay, mã đặt chỗ — lúc cần là có, không phải lục tin nhắn.

Checklist nhóm khác checklist một người ở chỗ có đồ chung — loa, sạc dự phòng, thuốc, bộ sơ cứu, ổ cắm nhiều lỗ — mà nếu không ghi tên thì hoặc không ai mang, hoặc ba người cùng mang. Cột B chọn Chung hoặc Cá nhân bằng danh sách thả xuống (cách làm ở bài tạo danh sách thả xuống trong Google Sheets), cột C ghi ai mang, cột D là ô tích (Chèn ▸ Hộp kiểm).

=COUNTIF(D2:D60; TRUE) & "/" & COUNTA(A2:A60) & " món"

=COUNTIFS(B2:B60; "Chung"; C2:C60; "")

Thử lại: danh sách 25 món, đã tích 18 → "18/25 món". Trong ví dụ trên, loa bluetooth là đồ chung chưa có tên → ô thứ hai ra 1. Hai ngày trước khi đi, trưởng đoàn chỉ cần nhìn ô này về 0.

Mục tiêu của bảng dự trù là trả lời một câu: mỗi người cần chuẩn bị bao nhiêu tiền. Mỗi hạng mục ghi đơn giá, số lượng (người, phòng, xe) và số ngày; thành tiền tự nhân. Cột G ghi khoản đó trả trước (phải đặt cọc, mua vé) hay dọc đường.

Ô J1 là số người (6), J2 là tỷ lệ dự phòng (10%). Các hạng mục ở dòng 2–7, cột C chỉ ghi số (6, 2, 3), không ghi chữ "người".

=IF(B2=""; ""; B2 * C2 * MAX(1; D2))

=SUM(E2:E7)
=ROUND(E8 * $J$2; -3)

=ROUNDUP((E8 + E9) / $J$1; -4)

=ROUNDUP(SUMIFS(E2:E7; G2:G7; "Trả trước") / $J$1; -4)

Thử lại: homestay 900.000 × 2 phòng × 2 đêm = 3.600.000; xe 600.000 × 6 × MAX(1; ô trống) = 3.600.000. Tổng 5 hạng mục = 13.500.000, dự phòng 1.350.000. (13.500.000 + 1.350.000) ÷ 6 = 2.475.000 → làm tròn lên 2.480.000. Khoản trả trước: 3.600.000 + 3.600.000 = 7.200.000 ÷ 6 = 1.200.000.

Có người không tham gia một khoản (đi xe riêng, không đi tham quan)? Bảng dự trù chỉ cần con số gần đúng để chuẩn bị tiền; ghi chú lại khoản đó và để phần tính chính xác cho lúc chia tiền cuối chuyến, nơi mỗi khoản chỉ chia cho người tham gia.

Quy tắc dễ thống nhất nhất: góp trước đúng phần phải trả trước (vé xe, cọc phòng) — trong ví dụ là 1.200.000đ mỗi người — còn tiền ăn, vé tham quan thì dọc đường tính. Góp cả 2.480.000đ ngay từ đầu cũng được, nhưng thủ quỹ phải cầm nhiều tiền hơn và cuối chuyến trả lại nhiều hơn.

1. Chọn một thủ quỹ — thường là người đặt xe hoặc đặt phòng, vì họ là người phải chuyển tiền cọc.
2. Đặt hạn góp trước ngày đặt cọc ít nhất 2–3 ngày. Ví dụ phòng phải cọc ngày 25/10 thì hạn góp 22/10.
3. Ghi nội dung chuyển khoản thống nhất, ví dụ "DALAT TEN", để thủ quỹ đối chiếu sao kê. Gửi kèm mã QR đúng số tiền thì không ai chuyển nhầm — cách tạo ở bài tạo mã QR chuyển khoản trong Google Sheets.
4. Ghi mỗi lần góp một dòng: ngày, người góp, số tiền. Tổng đã góp, đã chi từ quỹ và quỹ còn lại phải luôn nhìn thấy.

Bảng chia việc giống một bảng công việc nhỏ: việc, người phụ trách, hạn, ô tích xong. Cách đặt việc theo tuần, hạn chót và ưu tiên ở bài mẫu kế hoạch công việc tuần; với chuyến đi thì chừng này là đủ:

Tô đỏ việc quá hạn chưa xong: chọn vùng A2:D20, Định dạng ▸ Định dạng có điều kiện, chọn "Công thức tuỳ chỉnh" và dán công thức dưới. Cột D là ô tích, C là hạn.

=AND($D2 = FALSE; $C2 <> ""; $C2 < TODAY())

Ai trả gì nên chốt trước khi đi, ghi luôn vào trang dự trù (cột Ai lo và Khi nào trả):

• Khoản trả trước (xe, phòng): thủ quỹ hoặc người phụ trách trả từ tiền quỹ.
• Khoản dọc đường: một người cầm quỹ trả, hoặc ai tiện trả nấy — miễn là ghi lại ngay lúc trả: ngày, nội dung, số tiền, ai trả, ai tham gia.
• Khoản riêng (quà mang về, đồ uống riêng): ai dùng người đó trả, không đưa vào quỹ.
• Thống nhất trước chuyện trẻ em, người không uống bia, người đi muộn một ngày — sau chuyến mới bàn là dễ mất vui.

Dự trù chỉ có ích nếu trong chuyến có người ghi thực chi. Dùng cùng tên hạng mục với bảng dự trù (Di chuyển, Phòng, Ăn uống, Vé & vui chơi…) thì cuối chuyến so được ngay hạng mục nào vượt. Ở trang dự trù, thêm cột thực chi cộng từ trang chi tiêu:

=SUMIFS(ChiTieu!$D$2:$D$200; ChiTieu!$C$2:$C$200; A2)

Cuối chuyến, mỗi người có một con số: đã góp + đã tự trả − phần phải chịu. Cách tính, cách ghép để ít lần chuyển khoản nhất và công thức đầy đủ ở bài cách chia tiền đi chơi nhóm.

1. 

   Đi chơi về chia tiền: mỗi người một mã QR chuyển đúng số

   Xem trên YouTube ↗

• Cách chia tiền đi chơi nhómSố dư mỗi người, quỹ chung, ít lần chuyển khoản nhất
• Tạo mã QR chuyển khoản trong Google SheetsMã VietQR đúng số tiền, đúng nội dung
• Mẫu kế hoạch công việc tuầnChia việc, hạn chót, theo dõi tiến độ
• Tạo danh sách thả xuống trong Google SheetsChọn hạng mục, loại đồ thay vì gõ tay