Hàm IMPORTRANGE trong Google Sheets: lấy dữ liệu từ file khác, gộp nhiều file chi nhánh và sửa lỗi #REF!

Trong cùng một file, bạn lấy dữ liệu trang khác bằng 'Đơn hàng'!A2:D. Khi dữ liệu nằm ở file khác — mỗi chi nhánh một file, kế toán giữ file lương riêng, đội bán hàng có file riêng — thì cần IMPORTRANGE. Hàm này kéo một vùng ô từ file nguồn về file đích; file nguồn đổi số thì file đích đổi theo.

Đối số

Link hoặc ID file nguồn; "Tên trang!vùng ô"

Lần đầu

Bấm "Cho phép truy cập" một lần cho mỗi file nguồn

Giới hạn

10 MB dữ liệu nhận về mỗi yêu cầu

Cập nhật

Khi file nguồn đổi, và tự kiểm tra mỗi giờ khi file đang mở

Ví dụ trong bài: một cửa hàng có 3 chi nhánh Quận 1, Quận 3, Thủ Đức. Mỗi chi nhánh có một file riêng, trang Đơn hàng gồm A = Ngày, B = Mã đơn, C = Nhân viên, D = Doanh thu. Chủ cửa hàng muốn một file tổng hợp tự cập nhật mà không phải chép tay mỗi tối.

=IMPORTRANGE(url_bảng_tính; chuỗi_dải_ô)

Cách gọn nhất là để link mỗi file ở một ô riêng, ví dụ B1 là link file Quận 1, rồi viết công thức trỏ tới ô đó. Đổi file nguồn chỉ cần dán link mới vào B1.

=IMPORTRANGE(B1; "'Đơn hàng'!A1:D")

Thử lại: file Quận 1 có 3 đơn: 02/10/2026 · Q1-01 · Lan · 1.200.000; 05/10/2026 · Q1-02 · Minh · 850.000; 09/10/2026 · Q1-03 · Lan · 2.000.000. Sau khi cho phép truy cập, A3:D3 là dòng tiêu đề, A4:D6 là 3 đơn trên. Chi nhánh thêm đơn thứ 4 thì nó tự hiện ở dòng 7.

Thay vì A1:D, bạn có thể dùng tên của dải ô được đặt tên trong file nguồn, ví dụ "DonHang". Dải ô được đặt tên đi theo dữ liệu khi người ta đổi tên trang hay chèn cột, nên ít gãy hơn gõ tay "'Đơn hàng'!A1:D".

Lần đầu file đích lấy dữ liệu từ một file nguồn mới, Google không trả dữ liệu ngay mà hỏi quyền. Sau vài giây ô công thức báo #REF!; di chuột hoặc bấm vào ô sẽ thấy dòng "Bạn cần phải kết nối các trang tính này" và nút Cho phép truy cập.

• Bạn phải có ít nhất quyền xem file nguồn. Không có quyền thì Google báo bạn không có quyền truy cập trang tính; mở link file nguồn, xin quyền và chờ chủ file chấp nhận.
• Mỗi file nguồn cho phép một lần. File tổng hợp lấy từ 3 chi nhánh thì phải bấm cho phép 3 lần, mỗi file một lần. Lần sau thêm IMPORTRANGE khác từ cùng file đó thì không phải bấm nữa.
• Quyền đi theo người bấm. Theo Google, quyền này còn hiệu lực cho tới khi người đã bấm cho phép bị gỡ khỏi file nguồn.

Thường bạn không cần cả bảng mà chỉ một phần: đơn trên 1 triệu, đơn của một nhân viên, tổng theo người. Bọc IMPORTRANGE trong QUERY. Vì dữ liệu lúc này là mảng chứ không phải dải ô thường, QUERY không hiểu cột A, B mà phải gọi theo vị trí Col1, Col2, Col3, Col4.

=QUERY(IMPORTRANGE(B1; "'Đơn hàng'!A1:D"); "select Col2, Col3, Col4 where Col4 >= 1000000"; 1)

Thử lại: trong 3 đơn của Quận 1, chỉ Q1-01 (1.200.000) và Q1-03 (2.000.000) từ 1 triệu trở lên. Kết quả: dòng tiêu đề + 2 dòng: Q1-01 · Lan · 1.200.000 và Q1-03 · Lan · 2.000.000.

=QUERY(IMPORTRANGE(B1; "'Đơn hàng'!A1:D"); "select Col3, sum(Col4) where Col3 is not null group by Col3 label sum(Col4) 'Doanh thu'"; 1)

Thử lại: Lan = 1.200.000 + 2.000.000 = 3.200.000, Minh = 850.000. Viết WHERE, GROUP BY, lọc theo ngày trong QUERY có ở bài hàm QUERY trong Google Sheets.

Muốn dùng FILTER, đặt kết quả IMPORTRANGE vào một tên bằng LET để khỏi gọi hai lần, rồi lấy cột thứ 3 bằng INDEX(d; 0; 3):

=LET(d; IMPORTRANGE(B1; "'Đơn hàng'!A2:D"); FILTER(d; INDEX(d; 0; 3)="Lan"))

Thử lại: ra 2 dòng của Lan: Q1-01 và Q1-03.

Để xếp dữ liệu 3 chi nhánh chồng lên nhau thành một bảng, đặt các IMPORTRANGE trong ngoặc nhọn, cách nhau bằng dấu chấm phẩy. B1, B2, B3 là link 3 file.

=QUERY({IMPORTRANGE(B1; "'Đơn hàng'!A2:D"); IMPORTRANGE(B2; "'Đơn hàng'!A2:D"); IMPORTRANGE(B3; "'Đơn hàng'!A2:D")}; "select * where Col1 is not null"; 0)

Thử lại: Quận 1 có 3 đơn, Quận 3 có 2 đơn (600.000 và 1.500.000), Thủ Đức có 4 đơn (900.000, 700.000, 1.100.000, 300.000). Kết quả là 9 dòng liền nhau, tổng cột thứ 4 là 4.050.000 + 2.100.000 + 3.000.000 = 9.150.000. Không có QUERY bọc ngoài thì giữa các chi nhánh là cả trăm dòng trống.

Vì sao là dấu \? Theo trợ giúp của Google, ở những vùng dùng dấu phẩy làm dấu thập phân, dấu phẩy ghép cột trong mảng được thay bằng dấu gạch chéo ngược. Vùng Việt Nam viết số là 1.234,5 nên thuộc nhóm này. Dấu ; để xếp xuống dòng dưới thì giống nhau ở mọi vùng. Kiểm vùng của file ở Tệp › Cài đặt.

Bảng gộp cần biết dòng nào của chi nhánh nào. Ghép thêm một cột chữ bên phải mỗi phần bằng dấu \ :

=QUERY({
LET(q; IMPORTRANGE(B1; "'Đơn hàng'!A2:D"); {q \ ARRAYFORMULA(IF(INDEX(q; 0; 1)=""; ""; "Quận 1"))});
LET(q; IMPORTRANGE(B2; "'Đơn hàng'!A2:D"); {q \ ARRAYFORMULA(IF(INDEX(q; 0; 1)=""; ""; "Quận 3"))});
LET(q; IMPORTRANGE(B3; "'Đơn hàng'!A2:D"); {q \ ARRAYFORMULA(IF(INDEX(q; 0; 1)=""; ""; "Thủ Đức"))})
}; "select * where Col1 is not null"; 0)

ARRAYFORMULA ở đây biến chữ "Quận 1" thành cả một cột dài bằng dữ liệu, dòng trống thì để trống — cách hoạt động có ở bài hàm ARRAYFORMULA trong Google Sheets. Đặt công thức trên ở trang Gộp, rồi làm báo cáo từ trang đó thay vì gọi IMPORTRANGE lại lần nữa:

=QUERY('Gộp'!A1:E; "select E, count(B), sum(D) where A is not null group by E label E 'Chi nhánh', count(B) 'Số đơn', sum(D) 'Doanh thu'"; 0)

Nếu IMPORTRANGE từng chạy rồi bỗng báo không lấy được dữ liệu, hỏi chủ file nguồn xem họ có bật tuỳ chọn tắt tải xuống, in và sao chép không. Theo Google, khi tuỳ chọn này bật, IMPORTRANGE mới không lấy được dữ liệu từ file đó; công thức đã có từ trước vẫn chạy.

• 10 MB mỗi yêu cầu. Dữ liệu được tải về máy bạn, nên mạng chậm thì file đích cũng chậm.
• Cập nhật: file nguồn có thay đổi thì file đích đang mở tự làm mới (thanh tải màu xanh). Ngoài ra Google tự kiểm tra mỗi giờ khi file đang mở. Mở lại file không chắc làm mới ngay.
• Chuỗi nhiều tầng thì chậm. File A lấy từ B, B lấy từ C: mỗi tầng phải chờ tầng trước tính xong. Hai file lấy vòng của nhau thì không ra kết quả.
• Hạn mức tính theo người tạo file, cộng dồn mọi hàm IMPORT trong mọi file họ tạo. Công thức có đối số thay đổi liên tục dễ bị Google hạn chế.

Mẹo giữ file nhẹ: tóm tắt ngay trong file nguồn (một trang Tổng hợp nhỏ do chi nhánh tự tính), rồi chỉ IMPORTRANGE vùng tóm tắt đó; mỗi file nguồn chỉ gọi IMPORTRANGE một lần về một trang riêng, các báo cáo khác tham chiếu trang đó. Bài Google Sheets hay Excel có nói khi nào Google Sheets bắt đầu chậm vì nhiều IMPORTRANGE.

Nếu bạn gộp file chỉ vì mỗi cửa hàng có một file riêng, cách bền hơn là để mọi cửa hàng ghi vào cùng một file có cột Kho/Cửa hàng ngay từ đầu. Khi đó báo cáo theo từng cửa hàng chỉ là một bộ lọc, không có bước cấp quyền, không chờ đồng bộ.

Đây là chỗ nhiều người không ngờ. Theo trợ giúp của Google, sau khi đã cho phép, mọi người có quyền chỉnh sửa file đích đều dùng được IMPORTRANGE để lấy bất kỳ phần nào của file nguồn, không chỉ vùng bạn đã chọn.

Ví dụ: file lương của kế toán có trang Bảng lương và trang Tổng quỹ lương. Bạn IMPORTRANGE trang Tổng quỹ lương sang file báo cáo rồi chia sẻ quyền sửa file báo cáo cho trưởng nhóm. Trưởng nhóm chỉ cần sửa chuỗi thành "'Bảng lương'!A:Z" là thấy lương từng người, dù chưa bao giờ được chia sẻ file lương.

• Người chỉ có quyền xem file đích thấy được những gì IMPORTRANGE đang hiện, dù họ không có quyền vào file nguồn.
• Khoá ô, khoá trang không che dữ liệu. Bảo vệ trang tính chỉ chặn sửa, không chặn xem hay chặn lấy dữ liệu — xem cách khoá ô công thức trong Google Sheets.
• Dùng file trung gian. Chỉ đưa phần được phép chia sẻ (ví dụ tổng quỹ lương theo phòng) sang một file riêng, rồi IMPORTRANGE từ file trung gian đó. File gốc nhạy cảm không bao giờ được kết nối trực tiếp.
• Thu hồi quyền: quyền IMPORTRANGE còn tới khi người đã bấm cho phép bị gỡ khỏi file nguồn. Người đó nghỉ việc thì gỡ họ khỏi file nguồn.

Với dữ liệu khách hàng của đội bán hàng, thay vì chia file theo từng người rồi gộp lại, mẫu Quản lý Lead & Bán hàng PRO có portal trên điện thoại: mỗi nhân viên một link riêng, chỉ thấy lead của mình, không cần quyền mở trang tính (phần này dùng Apps Script, chỉ chạy trên Google Sheets).

• Hàm ARRAYFORMULA trong Google SheetsMột công thức cho cả cột, sửa lỗi #REF! khi mảng bị chặn
• Hàm QUERY trong Google SheetsLọc, cộng theo nhóm dữ liệu lấy về
• Hàm SUMIFS và COUNTIFSCộng, đếm theo nhiều điều kiện trên trang đã gộp
• Google Sheets hay ExcelLấy dữ liệu file khác ở hai bên khác nhau thế nào