Checklist chuẩn bị đám cưới: các lễ, mốc thời gian và ngân sách hai nhà
Checklist chuẩn bị đám cưới theo từng mốc 12 tháng → ngày cưới: các lễ dạm ngõ, ăn hỏi, rước dâu, việc cần làm, cách chia ngân sách nhà trai nhà gái.
Đám cưới & đi chơi · 13 phút đọc
Ghi sổ tiền mừng cưới gọn nhất là **mỗi phong bì một dòng**: số phong bì, lễ, phía, nhóm khách, tên người mừng, số tiền và hình thức (tiền mặt, chuyển khoản, hiện vật). Có đủ các cột đó thì tổng theo nhà trai, nhà gái, nhóm khách chỉ là một công thức, và cuối tiệc bạn đối chiếu được tiền mặt đếm tay với sổ. Bài này đi qua các cột cần có, cách nhận phong bì trong ngày cưới để không thất lạc, bảng Google Sheets tự làm với công thức thử lại được, và cách tra lại ai mừng bao nhiêu khi sau này đi đáp lễ.

Quản lý đám cưới trên Google Sheets: khách mời, RSVP điện thoại, bàn tiệc, ngân sách | HiTaVa
Xem trên YouTube ↗Nhiều nhà vẫn ghi sổ mừng bằng một cuốn vở: tên và số tiền. Đủ để nhớ, nhưng không đủ để trả lời những câu hỏi sẽ tới ngay sau tiệc: tiền mặt đếm được có khớp sổ không, nhà trai nhận bao nhiêu, nhà gái bao nhiêu, phong bì không ghi tên là của ai, và vài năm sau, khi nhận thiệp của anh đồng nghiệp, ngày xưa anh ấy mừng mình thế nào.
Muốn trả lời được, mỗi phong bì cần thêm vài thông tin nhỏ. Bảng dưới là bộ cột đủ dùng cho một đám cưới có nhiều lễ và hai nhà:
| Cột | Ghi gì | Vì sao cần |
|---|---|---|
| Số phong bì | 1, 2, 3… viết lên góc phong bì lúc nhận | Đối chiếu từng phong bì với sổ, phát hiện ghi trùng hoặc sót |
| Lễ | Ăn hỏi, tiệc nhà gái, tiệc nhà trai… | Mỗi lễ đếm tiền một lần, đối chiếu riêng |
| Phía | Nhà trai / nhà gái | Tổng mỗi nhà, nhất là khi hai nhà tổ chức tiệc riêng |
| Nhóm | Họ hàng, bạn cô dâu, bạn chú rể, đồng nghiệp, hàng xóm | Biết mỗi nhóm mừng bao nhiêu, gửi lời cảm ơn theo nhóm |
| Người mừng | Tên kèm chỗ quen: "Anh Tuấn (phòng kế toán)" | Tên trùng rất hay gặp; vài năm sau vẫn nhận ra |
| Số tiền | Chỉ ghi số: 500000, không ghi "500k" | Để công thức cộng được |
| Hình thức | Tiền mặt / Chuyển khoản / Hiện vật | Chỉ tiền mặt mới đem đối chiếu với tiền đếm tay |
| Hiện vật / ghi chú | 1 chỉ vàng, bộ chăn ga; "4 người chung 1 phong bì" | Quà không quy ra tiền vẫn phải nhớ |
| Người nhận | Ai cầm phong bì | Lệch tiền thì biết hỏi ai |
| Đã cảm ơn | Tick khi đã nhắn cảm ơn | Không sót người |
| Đáp lễ | Ngày và số tiền khi mình đi lại | Lần sau khỏi phải nhớ |
"500k" là chữ, không phải số
Gõ "500k" hoặc "1tr" vào ô số tiền thì Google Sheets coi là chữ và SUM bỏ qua, tổng ra thiếu mà không báo lỗi. Gõ 500000, rồi định dạng ô là số có dấu chấm nghìn. Nếu sổ đã lỡ ghi kiểu đó, xem cách sửa ở bài SUM bằng 0 trong Google Sheets.
Phần lớn chuyện thất lạc phong bì không phải do ai lấy, mà do phong bì đi qua quá nhiều tay mà không ai ghi: khách đưa cho cô dâu lúc chụp ảnh, mẹ cầm hộ bỏ túi áo, phong bì rơi sau thùng. Một quy trình đơn giản, thống nhất trước với người nhà, giải quyết gần hết:
Phong bì ghi "Gia đình anh Hùng" mà nhà có hai anh Hùng? Ghi đúng như trên phong bì, thêm "cần hỏi lại" vào ghi chú, sau tiệc hỏi bố mẹ. Phong bì hoàn toàn không tên: vẫn đánh số, ghi "Không tên" cùng số tiền — để tổng tiền khớp, rồi tìm dần qua người quen.
Phong bì góp chung (cả nhóm bạn một phong bì) cứ ghi một dòng, nhưng nên ghi rõ ai trong nhóm ở cột ghi chú. Sau này mỗi người trong nhóm cưới, bạn sẽ cần thông tin đó.
Tạo một tab tên Sổ mừng, hàng 1 là tiêu đề, mỗi phong bì một dòng từ hàng 2. Cột A tới K theo đúng thứ tự ở bảng trên. Với Lễ, Phía, Nhóm, Hình thức, nên tạo danh sách thả xuống (Dữ liệu › Xác thực dữ liệu › Thả xuống) để không ai gõ "nhà trai", "Nha trai", "NT" lẫn lộn — công thức chỉ cộng đúng khi chữ giống hệt nhau.

Tổng theo nhà trai, nhà gái. Cột C là Phía, F là Số tiền:
=SUMIFS(F:F; C:C; "Nhà trai")Tổng theo nhóm khách (cột D) và tổng tiền mặt của một lễ (cột B Lễ, cột G Hình thức):
=SUMIFS(F:F; D:D; "Họ hàng")
=SUMIFS(F:F; B:B; "Tiệc nhà trai"; G:G; "Tiền mặt")Đếm số phong bì có tiền của nhà trai (bỏ dòng hiện vật):
=COUNTIFS(C:C; "Nhà trai"; F:F; ">0")Một bảng tổng theo nhóm, tự sắp xếp — đặt ở tab khác, một công thức ra cả bảng:
=QUERY('Sổ mừng'!A1:K; "select D, count(F), sum(F) where F > 0 group by D order by sum(F) desc"; 1)Báo trùng số phong bì. Chọn cột A, vào Định dạng › Định dạng có điều kiện › Công thức tuỳ chỉnh, dán công thức dưới và chọn nền đỏ. Hai dòng cùng số phong bì nghĩa là ghi trùng hoặc đánh số nhầm — đúng thứ làm lệch tiền.
=AND($A2<>""; COUNTIF($A:$A; $A2)>1)Thử lại với 8 phong bì trong hình. Nhà trai gồm phong bì 4, 5, 6, 7: 3.000.000 + 300.000 + 2.000.000 + 500.000 = 5.800.000. Nhà gái gồm 1, 2, 3 (phong bì 8 là hiện vật, không có số tiền): 2.000.000 + 500.000 + 1.000.000 = 3.500.000. Nhóm Họ hàng: phong bì 1 và 4 = 5.000.000. Tiền mặt tiệc nhà trai: phong bì 4, 5, 6 = 5.300.000 (phong bì 7 chuyển khoản nên không tính). COUNTIFS nhà trai ra 4. Nếu bảng của bạn ra khác, gần như chắc chắn là chữ ở cột Phía hoặc Lễ gõ chưa giống nhau.
Sổ mừng là dữ liệu riêng tư. Đừng để chung trong file kế hoạch cưới đã chia sẻ cho cả nhà: Google Sheets không khoá được việc xem từng tab, ai mở được file là xem được mọi tab. Tách sổ mừng ra một file riêng, chỉ hai vợ chồng mở. Muốn chặn người khác lỡ tay sửa công thức thì xem cách khoá ô công thức.
Đối chiếu nghĩa là so hai con số: tiền mặt sổ ghi của một lễ và tiền mặt đếm được của lễ đó. Làm ngay trong đêm, khi mọi người còn nhớ ai đưa gì — để tới tuần sau thì gần như không tìm ra chỗ lệch.
Cách đếm ít nhầm nhất là theo mệnh giá: xếp tờ 500.000 riêng, 200.000 riêng, 100.000 riêng… đếm số tờ từng loại, rồi nhân. Làm một tab nhỏ tên Đếm tiền: cột A mệnh giá, cột B số tờ.

=SUMPRODUCT(A2:A5; B2:B5)=SUMPRODUCT(A2:A5; B2:B5) - SUMIFS('Sổ mừng'!F:F; 'Sổ mừng'!B:B; "Tiệc nhà trai"; 'Sổ mừng'!G:G; "Tiền mặt")Thử lại: 10 tờ 500.000 = 5.000.000, 1 tờ 100.000 = 100.000, đếm được 5.100.000. Sổ ghi tiền mặt tiệc nhà trai 5.300.000. Lệch −200.000.
Lệch rồi thì soát theo thứ tự này, thường tìm ra ở một trong ba bước đầu:
Đếm riêng từng lễ
Đừng dồn tiền ăn hỏi, tiệc nhà gái, tiệc nhà trai vào một túi rồi đếm một lần. Lệch 200.000 trên tổng ba lễ khó tìm hơn nhiều so với lệch 200.000 trong một lễ chỉ có vài chục phong bì.
Nếu bạn đang lo cả khách mời, bàn tiệc, ngân sách, mẫu Quản lý đám cưới PRO có sẵn phần sổ mừng làm đúng những việc ở trên, và tách sổ ra một file riêng chỉ cô dâu chú rể mở — file chính chia sẻ cho gia đình không chứa tiền mừng. Trên Google Sheets, lần chạy Cài đặt file đầu tiên, script tự tạo file "Sổ mừng cưới — riêng tư" trong Drive của bạn.

Sổ mừng còn dùng nhiều năm sau đám cưới. Khi nhận thiệp, bạn chỉ cần gõ tên vào một ô tìm kiếm. Giả sử ô N1 là chữ cần tìm:
=FILTER('Sổ mừng'!A2:K; ISNUMBER(SEARCH(N1; 'Sổ mừng'!E2:E)))SEARCH không phân biệt hoa thường nhưng có phân biệt dấu: gõ "Luc" sẽ không ra "Lực". Vì vậy cột Người mừng nên ghi kèm chỗ quen ("phòng kế toán", "bạn cấp 3") — tìm theo chỗ quen nhiều khi nhanh hơn tìm theo tên.
Mỗi lần đi đáp lễ, ghi ngày và số tiền vào cột Đáp lễ của đúng dòng đó. Sổ trở thành một cuốn "sổ giao tế" của gia đình, lần sau không phải ngồi nhớ. Cột Đã cảm ơn nên tick trong tuần đầu sau cưới: lọc các dòng chưa tick là ra danh sách cần nhắn.
Bạn đang lo các phần khác của đám cưới thì đọc thêm checklist chuẩn bị đám cưới theo từng mốc, và cách tính số bàn tiệc cưới từ danh sách khách theo hộ.
Không nên. Trong lúc tiệc chỉ cần đánh số phong bì và ghi tên người mừng. Mở và ghi số tiền sau khi tiệc xong, có ít nhất hai người, đếm riêng từng lễ — vừa đỡ rối, vừa đối chiếu được.
Ghi mỗi khoản một dòng như phong bì, hình thức Chuyển khoản, dán nội dung chuyển khoản vào ghi chú để nhận ra người gửi. Khoản chuyển khoản không đem đối chiếu với tiền mặt đếm tay; đối chiếu nó với lịch sử giao dịch trong ứng dụng ngân hàng.
Không bắt buộc. Để trống số tiền, ghi món quà vào cột hiện vật. Nếu muốn biết tổng giá trị, thêm một cột "Giá trị ước tính" riêng, đừng trộn vào cột Số tiền vì sẽ làm lệch khi đối chiếu tiền mặt.
Thường là cô dâu chú rể. Nếu làm trên Google Sheets, để sổ mừng ở file riêng chỉ hai vợ chồng mở; người thu phong bì chỉ cần ghi, không cần xem tổng. Hai nhà tổ chức tiệc riêng thì thống nhất trước tiền tiệc nhà nào nhà đó giữ hay gộp chung.
Bạn tự dựng được theo 11 cột và các công thức trong bài; SUMIFS, COUNTIFS, SUMPRODUCT chạy cả trên Excel (Excel dùng dấu phẩy hay chấm phẩy tuỳ cài đặt vùng). Mẫu Quản lý đám cưới PRO có file sổ mừng .xlsx với công thức tổng hợp, chạy trên Excel 2016 trở lên; ghi phong bì trên điện thoại chỉ có ở bản Google Sheets.
Checklist chuẩn bị đám cưới theo từng mốc 12 tháng → ngày cưới: các lễ dạm ngõ, ăn hỏi, rước dâu, việc cần làm, cách chia ngân sách nhà trai nhà gái.
Đám cưới hết bao nhiêu tiền và cách lập ngân sách đám cưới: chia khoản theo nhà trai, nhà gái, theo từng lễ, đi từ dự toán tới báo giá, thực tế và dự phòng.
Mừng cưới bao nhiêu tiền là hợp lý: 5 yếu tố quyết định, cách tính mức sàn theo suất ăn, mừng đồng nghiệp, bạn thân, không đi được thì chuyển khoản thế nào.
Thực đơn đám cưới gồm khai vị, món chính, lẩu, tráng miệng, đồ uống. Số món thường gặp, thực đơn tiệc cưới mẫu 3 miền, món chay, tính bia theo két.
Xem thêm mẹo và video hướng dẫn trên kênh YouTube HiTaVa, hoặc đọc các bài khác trong chủ đề Đám cưới & đi chơi.
Cần hỏi thêm?Zalo 0935077673 (Hải Vân)