hitava

Đám cưới & đi chơi · 12 phút đọc

Trả nợ nhiều khoản trả khoản nào trước? Snowball, Avalanche và cách tính trên Google Sheets

Có nhiều khoản nợ thì luôn trả đủ mức tối thiểu của mọi khoản, rồi dồn toàn bộ tiền trả thêm vào **một** khoản: khoản lãi suất cao nhất (Avalanche — tốn ít tiền lãi nhất) hoặc khoản dư nợ nhỏ nhất (Snowball — xong khoản đầu sớm nhất, dễ giữ động lực). Trong ví dụ giả định 3 khoản 89 triệu trả 6 triệu mỗi tháng, cả hai cách hết nợ sau 18 tháng, Avalanche đỡ khoảng 728.000đ tiền lãi, còn chỉ trả tối thiểu thì mất 35 tháng và gần gấp đôi tiền lãi. Bài này đi qua cách liệt kê nợ, tính lãi tháng, ước số tháng bằng NPER, dựng bảng lịch trả theo tháng trên Google Sheets và khi nào nên nghĩ tới vay gộp.

Đăng HiTaVaTrả nợThẻ tín dụngSnowballAvalancheGoogle Sheets
Ba thẻ so sánh với 3 khoản nợ 89 triệu: chỉ trả tối thiểu 35 tháng, lãi 29.065.153đ; Snowball 18 tháng, lãi 16.195.127đ; Avalanche 18 tháng, lãi 15.467.534đ

Trả nợ nhiều khoản: trả khoản nào trước?

Hai luật dùng cho mọi cách trả:

  1. Không bao giờ bỏ mức tối thiểu của khoản nào. Trễ hạn thường kéo theo phí phạt, lãi phạt và ghi nhận nợ quá hạn — tốn hơn mọi khoản lãi bạn định tiết kiệm.
  2. Giữ nguyên tổng tiền trả mỗi tháng. Khi một khoản xong, tiền tối thiểu của nó không quay về chi tiêu mà dồn sang khoản kế tiếp. Chính phần "lăn" này làm nợ hết nhanh.

Khác nhau chỉ ở thứ tự nhận tiền trả thêm:

Avalanche (tuyết lở)
Lãi suất cao nhất trước — ít tiền lãi nhất
Snowball (quả cầu tuyết)
Dư nợ nhỏ nhất trước — xong khoản đầu sớm nhất
Ví dụ 89 triệu, 6 triệu/tháng
Cả hai 18 tháng; Avalanche đỡ 727.593đ
Chỉ trả tối thiểu
35 tháng, lãi 29.065.153đ

Tất cả số trong bài là số giả định để minh hoạ cách tính, không phải lãi suất thị trường. Hãy thay bằng dư nợ và lãi suất trên sao kê, hợp đồng của chính bạn.

Bước 1: liệt kê nợ — dư nợ, lãi suất năm, trả tối thiểu

Mỗi khoản nợ một dòng, bốn cột: A tên, B dư nợ hiện tại, C lãi suất năm, D số tiền trả tối thiểu mỗi tháng. Ví dụ dùng suốt bài:

Khoản (giả định)Dư nợLãi suất nămTrả tối thiểu/tháng
Thẻ tín dụng30.000.00030%1.500.000
Vay tiêu dùng50.000.00020%1.900.000
Trả góp xe máy9.000.00012%800.000
Tổng89.000.0004.200.000
Tổng tiền trả mỗi tháng trong ví dụ là 6.000.000: 4.200.000 tối thiểu + 1.800.000 trả thêm.
  • Dư nợ: thẻ tín dụng xem trên sao kê hoặc app; khoản vay xem dư nợ gốc còn lại trong app ngân hàng hoặc lịch trả nợ.
  • Lãi suất: lấy theo năm. Hợp đồng ghi theo tháng thì nhân 12. Khoản trả góp "0%" nhưng có phí chuyển đổi thì lãi thật không phải 0.
  • Trả tối thiểu: thẻ tín dụng thường là một phần trăm dư nợ sao kê nên giảm dần khi nợ giảm; ví dụ trong bài giữ cố định cho dễ theo.

Với danh sách dài, đếm nhanh có bao nhiêu khoản lãi trên 20%/năm và cộng dư nợ của nhóm đó — nhóm cần dồn tiền trước nếu theo Avalanche:

Đếm khoản có lãi trên 20%: ra 1 (thẻ 30%; vay tiêu dùng đúng 20% không tính).
=COUNTIF(C2:C4;">"&0,2)
Dư nợ của các khoản lãi từ 20% trở lên: 30.000.000 + 50.000.000 = 80.000.000.
=SUMIF(C2:C4;">="&0,2;B2:B4)

Số thập phân trong điều kiện: viết ">"&0,2

Google Sheets vùng Việt Nam có thể hiểu sai chuỗi ">0.2" hoặc ">0,2" gõ liền trong ngoặc kép. Nối dấu so sánh với số bằng & như trên, hoặc trỏ tới một ô chứa 20%: ">"&F1. Cách viết điều kiện khác có ở bài hàm SUMIFS và COUNTIFS.

Cách tính lãi mỗi tháng của một khoản nợ

Cách ước đơn giản, cũng là cách bài này dùng: lãi tháng = dư nợ × lãi suất năm ÷ 12.

Thẻ tín dụng: 30.000.000 × 30% ÷ 12 = 750.000đ tiền lãi tháng đầu.
=ROUND(B2*C2/12;0)

Con số này cho thấy vì sao trả tối thiểu lâu đến vậy: trả 1.500.000 thì 750.000 đi vào lãi, chỉ 750.000 giảm gốc. Ba tháng đầu của thẻ nếu chỉ trả tối thiểu:

ThángDư nợ đầu thángLãi thángTrảDư nợ cuối tháng
130.000.000750.0001.500.00029.250.000
229.250.000731.2501.500.00028.481.250
328.481.250712.0311.500.00027.693.281

Lãi thật có thể khác

Ngân hàng thường tính lãi theo số ngày thực; với thẻ tín dụng, nếu không trả đủ dư nợ sao kê trước hạn, nhiều ngân hàng tính lãi trên cả khoản chi từ ngày giao dịch chứ không chỉ phần còn thiếu. Cách tính "÷ 12" chỉ là ước tính để so các phương án — đọc điều khoản thẻ và hợp đồng vay của bạn để biết cách tính chính xác.

Hàm NPER: ước số tháng trả hết một khoản nợ

NPER trả về số kỳ cần để trả hết một khoản khi lãi và số tiền trả mỗi kỳ cố định. Số tiền trả viết âm (tiền ra), dư nợ viết dương:

Số tháng trả hết khoản ở dòng 2, làm tròn lên tháng.
=ROUNDUP(NPER(C2/12;-D2;B2);0)

Thử lại với ba khoản nếu chỉ trả tối thiểu: thẻ NPER(30%/12; −1.500.000; 30.000.000) = 28,07 → 29 tháng; vay tiêu dùng 34,93 → 35 tháng; xe máy 11,99 → 12 tháng.

Tổng tiền lãi ước tính: thẻ 28,07 × 1.500.000 − 30.000.000 ≈ 12,1 triệu — gần một nửa dư nợ ban đầu.
=NPER(C2/12;-D2;B2)*D2-B2

NPER báo lỗi #NUM!

Khi số tiền trả mỗi tháng không lớn hơn tiền lãi tháng, khoản nợ không bao giờ hết và NPER báo lỗi. Ví dụ thẻ 30 triệu lãi 30% mà chỉ trả 700.000/tháng (lãi đã 750.000): nợ còn tăng lên. Đây là tín hiệu phải tăng tiền trả cho khoản đó ngay.

NPER chỉ dùng cho từng khoản riêng lẻ. Khi nhiều khoản cùng chạy và tiền của khoản đã xong được dồn sang khoản khác, phải dựng bảng theo tháng ở phần dưới.

Snowball và Avalanche khác nhau thế nào: ví dụ có số

Cùng ba khoản ở trên, mỗi tháng trả đúng 6.000.000. Mỗi tháng: cộng lãi tháng vào từng khoản, trả tối thiểu mọi khoản, phần còn lại dồn vào khoản đứng đầu thứ tự; khoản đó xong thì phần thừa chảy sang khoản kế.

  • Snowball xếp theo dư nợ tăng dần: xe máy 9 triệu → thẻ 30 triệu → vay tiêu dùng 50 triệu.
  • Avalanche xếp theo lãi suất giảm dần: thẻ 30% → vay tiêu dùng 20% → xe máy 12%. Xe máy là khoản lãi thấp nhất nên chỉ nhận tối thiểu và tự hết theo lịch.
Cách trảKhoản xong (tháng)Hết nợ sauTổng tiền lãi
Chỉ trả tối thiểu (4,2 triệu/tháng, giảm dần khi khoản xong)Xe máy 12 · thẻ 29 · vay 3535 tháng29.065.153
Snowball (6 triệu/tháng)Xe máy 4 · thẻ 11 · vay 1818 tháng16.195.127
Avalanche (6 triệu/tháng)Thẻ 11 · xe máy 12 · vay 1818 tháng15.467.534
Mô phỏng từng tháng, lãi = dư nợ × lãi năm ÷ 12, làm tròn đồng. Số giả định.
Biểu đồ thanh tháng trả xong từng khoản: Snowball xong trả góp xe máy tháng 4, thẻ tín dụng tháng 11, vay tiêu dùng tháng 18; Avalanche xong thẻ tháng 11, xe máy tháng 12, vay tiêu dùng tháng 18
Snowball xoá được một khoản sau 4 tháng; Avalanche dồn hết vào thẻ 30% nên đỡ lãi hơn.

Đọc bảng: trả thêm 1,8 triệu mỗi tháng (dù theo cách nào) rút từ 35 xuống 18 tháng và bớt gần 13 triệu tiền lãi — đây là phần quan trọng nhất. Giữa hai cách, Avalanche rẻ hơn 727.593đ vì 1,8 triệu trả thêm đi thẳng vào khoản 30% ngay từ tháng đầu, trong khi Snowball dành 4 tháng đầu cho khoản 12%.

Chênh lệch nhỏ ở ví dụ này vì khoản nhỏ nhất lại hết nhanh. Khi khoản dư nợ nhỏ có lãi thấp còn khoản lớn có lãi rất cao, hoặc khi tổng nợ lớn và kéo dài nhiều năm, khoảng cách giữa hai cách sẽ rộng hơn nhiều.

Nên chọn Snowball hay Avalanche

SnowballAvalanche
Thứ tựDư nợ nhỏ trướcLãi suất cao trước
Tổng tiền lãiBằng hoặc nhiều hơnThường ít nhất (cùng số tiền trả)
Khoản đầu tiên xongSớm nhấtCó thể rất lâu nếu khoản lãi cao là khoản lớn
Hợp khiNhiều khoản nhỏ lặt vặt, cần thấy kết quả sớm để không bỏ cuộcLãi suất các khoản chênh nhau nhiều, bạn đủ kiên nhẫn

Cách trả "tốt nhất" là cách bạn theo được tới cuối. Về số học, với cùng số tiền trả, Avalanche hầu như luôn tốn lãi ít hơn hoặc bằng Snowball. Nhưng nếu việc gạch được một khoản sau vài tháng giúp bạn giữ kỷ luật, Snowball đáng giá vài trăm nghìn chênh lệch. Một cách lai hay gặp: xoá ngay các khoản rất nhỏ (dưới một hai tháng tiền trả thêm) cho gọn, rồi chuyển sang Avalanche cho phần còn lại.

Tiền trả thêm lấy ở đâu? Từ phần để dành trong ngân sách tháng — xem quản lý chi tiêu cá nhân bằng Google Sheets để đặt ngân sách và thấy mỗi tháng còn dư bao nhiêu. Nên giữ một quỹ khẩn cấp nhỏ song song, để khi có việc bất ngờ bạn không phải quẹt thẻ lại.

Công thức Google Sheets mô phỏng lịch trả nợ theo tháng

Một khoản nợ. Dòng 1 tiêu đề, dòng 2 là tháng 1. Lãi suất năm ở $H$1, tiền trả mỗi tháng ở $H$2, dư nợ ban đầu ở $H$3. Các cột: A tháng, B dư nợ đầu tháng, C lãi, D trả, E dư nợ cuối tháng.

Kéo dòng 3 (và C2:E2) xuống tới khi E về 0. MIN ở cột D để tháng cuối chỉ trả đúng phần còn lại. Thử lại với thẻ: tháng 1 lãi 750.000, cuối tháng 29.250.000 — khớp bảng ở trên.
A2: 1
B2: =$H$3
C2: =ROUND(B2*$H$1/12;0)
D2: =MIN($H$2;B2+C2)
E2: =B2+C2-D2

A3: =A2+1
B3: =E2

Ba khoản cùng lúc (Snowball hoặc Avalanche). Ở A2:D4 là bảng liệt kê nợ (tên, dư nợ, lãi năm, tối thiểu), đã sắp xếp theo thứ tự ưu tiên: Snowball thì dư nợ tăng dần, Avalanche thì lãi suất giảm dần. Tổng tiền trả mỗi tháng ở B6 (6.000.000). Từ dòng 10: cột A tháng, B–D là dư nợ của khoản 1–3 sau khi cộng lãi tháng đó, E–G là tiền trả cho từng khoản, H là tổng dư nợ.

Khoản 1 nhận mọi tiền thừa sau khi chừa đủ tối thiểu cho khoản 2 và 3; khoản 2 nhận phần thừa khi khoản 1 đã xong; khoản 3 nhận phần còn lại. Chép E10:H10 xuống dòng 11, rồi kéo cả dòng 11 xuống tới dòng 369 (30 năm).
B10: =ROUND($B$2*(1+$C$2/12);0)
C10: =ROUND($B$3*(1+$C$3/12);0)
D10: =ROUND($B$4*(1+$C$4/12);0)

E10: =MIN(B10;$B$6-MIN(C10;$D$3)-MIN(D10;$D$4))
F10: =MIN(C10;$B$6-E10-MIN(D10;$D$4))
G10: =MIN(D10;$B$6-E10-F10)
H10: =B10+C10+D10

B11: =ROUND((B10-E10)*(1+$C$2/12);0)
C11: =ROUND((C10-F10)*(1+$C$3/12);0)
D11: =ROUND((D10-G10)*(1+$C$4/12);0)

Thử lại tháng 1 theo Avalanche (thẻ, vay tiêu dùng, xe máy): B10 = 30.750.000, C10 = 50.833.333, D10 = 9.090.000. E10 = MIN(30.750.000; 6.000.000 − 1.900.000 − 800.000) = 3.300.000; F10 = 1.900.000; G10 = 800.000. Tháng 11, thẻ chỉ còn 1.467.160 nên F nhận 6.000.000 − 1.467.160 − 800.000 = 3.732.840.

Theo Avalanche ra 18 tháng và 15.467.534đ; sắp lại A2:D4 theo dư nợ tăng dần (Snowball) ra 18 tháng và 16.195.127đ.
Số tháng hết nợ:  =COUNTIF(H10:H369;">"&0)
Tổng tiền lãi:    =SUM(E10:G369)-SUM(B2:B4)

Tổng tiền trả B6 phải lớn hơn hoặc bằng tổng các mức tối thiểu, nếu không cột E sẽ ra số âm. Muốn thấy dư nợ giảm qua các tháng, vẽ cột H thành biểu đồ đường — cách làm ở bài tạo biểu đồ trong Google Sheets.

Bảng Nợ và cho vay: Snowball trả khoản dư nợ nhỏ nhất trước và Avalanche trả khoản lãi suất cao nhất trước, mỗi bảng có thứ tự, khoản, dư nợ, lãi năm, trả tối thiểu, số tháng trả xong, tháng xong, tiền lãi ước tính; bảng so sánh ba cách và câu kết luận Avalanche đỡ 391.985đ
Cùng cách tính trong mẫu Tài chính cá nhân PRO (file DEMO, số khác ví dụ của bài): tự xếp thứ tự, mô phỏng tới 10 khoản và 30 năm.

Khi nào cân nhắc vay gộp để trả nợ

Vay gộp (vay một khoản mới để trả hết các khoản cũ) chỉ có lợi khi tổng tiền phải trả thật sự giảm. Ví dụ giả định: vay 89 triệu lãi 15%/năm để tất toán cả ba khoản.

Trả góp đều 18 tháng: 5.552.246đ/tháng, tổng lãi ≈ 5.552.246 × 18 − 89.000.000 = 10.940.429đ.
=PMT(15%/12;18;-89000000)
Phương án (giả định)Trả mỗi thángHết nợ sauTổng tiền lãi
Avalanche, giữ các khoản cũ6.000.00018 tháng15.467.534
Vay gộp 15%/năm, 18 tháng5.552.24618 tháng10.940.429 + phí
Vay gộp 15%/năm, 36 tháng3.085.21436 tháng22.067.713 + phí

Cùng một lãi suất gộp, kéo kỳ hạn lên 36 tháng làm tiền trả mỗi tháng nhẹ hẳn nhưng tổng lãi nhiều hơn cả việc tự trả theo Avalanche. Trước khi ký, tự kiểm bốn điều:

  1. Lãi suất khoản gộp thấp hơn lãi suất của các khoản cũ, tính trên cả thời gian vay chứ không chỉ năm đầu ưu đãi.
  2. Đã cộng mọi khoản phí: phí hồ sơ, bảo hiểm khoản vay, phí trả nợ trước hạn của các khoản cũ.
  3. Kỳ hạn không dài hơn thời gian bạn tự trả được — so tổng tiền lãi bằng PMT như trên, không chỉ so tiền trả mỗi tháng.
  4. Sau khi gộp không tiêu lại vào thẻ vừa trả hết; nếu không, bạn sẽ có cả khoản gộp lẫn nợ thẻ mới.

Bài viết chỉ minh hoạ cách tính với số giả định, không phải lời khuyên vay hay không vay. Điều kiện vay thực tế tuỳ từng ngân hàng và hồ sơ của bạn; hỏi rõ tổng chi phí khoản vay bằng văn bản trước khi quyết định.

Mẫu tính kế hoạch trả nợ làm sẵn

Bảng ở trên đủ cho ba khoản. Nếu bạn có nhiều khoản hơn và muốn mọi thứ nối với sổ thu chi — dư nợ tự giảm khi ghi tiền trả, thẻ tín dụng báo sắp đến hạn — mẫu dưới làm sẵn phần đó.

Tab Lịch trả nợ của khoản vay mua ô tô 300 triệu, lãi 9,5%/năm, 60 tháng, gốc đều lãi giảm dần: tổng tiền lãi, kỳ trả tới, dư nợ theo lịch và bảng từng kỳ với ngày trả, dư nợ đầu kỳ, gốc, lãi, tổng trả, dư nợ cuối kỳ
Lịch trả nợ từng kỳ trong mẫu (file DEMO). Lãi tính theo tháng nên là ước tính, ngân hàng có thể lệch ít.

Mẫu là công cụ ghi chép và tính theo số bạn nhập, không phải tư vấn tài chính.

Câu hỏi thường gặp

Nợ thẻ tín dụng và nợ vay, nên trả cái nào trước?

Trả đủ tối thiểu cả hai, rồi dồn tiền thêm vào khoản có lãi suất năm cao hơn (theo Avalanche). Thẻ tín dụng thường là khoản lãi cao, nhưng hãy so lãi suất thật trên sao kê và hợp đồng của bạn thay vì đoán.

Phương pháp Snowball là gì?

Là cách trả nợ dồn tiền thêm vào khoản có dư nợ nhỏ nhất, các khoản khác trả tối thiểu. Khoản nhỏ xong thì tiền của nó dồn sang khoản nhỏ kế tiếp, như quả cầu tuyết lăn to dần. Ưu điểm là thấy kết quả sớm; nhược điểm là có thể tốn lãi hơn Avalanche.

Có nên chỉ trả tối thiểu thẻ tín dụng không?

Chỉ trả tối thiểu giữ bạn khỏi trễ hạn nhưng phần lớn tiền đi vào lãi. Trong ví dụ, thẻ 30 triệu lãi giả định 30%/năm trả 1,5 triệu/tháng mất 29 tháng và khoảng 12,1 triệu tiền lãi. Trả thêm được bao nhiêu thì nên trả thêm.

Có tiền dư nên trả nợ hay gửi tiết kiệm?

So lãi suất: tiền trả bớt một khoản nợ lãi 20% giống như được "lãi" 20% chắc chắn, thường cao hơn lãi tiết kiệm. Nhiều người vẫn giữ một quỹ khẩn cấp nhỏ trước để không phải vay lại khi có việc gấp. Đây là cách so số học, không phải lời khuyên cho trường hợp riêng của bạn.

Tính số tháng trả hết nợ trong Excel, Google Sheets thế nào?

Dùng =ROUNDUP(NPER(lãi năm/12; -tiền trả mỗi tháng; dư nợ); 0). Ví dụ NPER(30%/12; -1500000; 30000000) ra 28,07, làm tròn lên 29 tháng. Nhiều khoản cùng lúc thì dựng bảng theo tháng như trong bài.

Trả nợ trước hạn có bị phạt không?

Tuỳ hợp đồng. Nhiều khoản vay có phí trả nợ trước hạn, nhất là trong những năm đầu. Đọc điều khoản hoặc hỏi ngân hàng trước khi dồn tiền tất toán sớm, và cộng phí đó vào phép so.

Đọc tiếp

Mẫu làm sẵn cho việc này

Đọc tiếp

Xem thêm mẹo và video hướng dẫn trên kênh YouTube HiTaVa, hoặc đọc các bài khác trong chủ đề Đám cưới & đi chơi.

Cần hỏi thêm?Zalo 0935077673 (Hải Vân)