# Quản lý lớp dạy thêm bằng Google Sheets: điểm danh, học phí, lương giáo viên

Quản lý lớp dạy thêm bằng Google Sheets xoay quanh một bảng: điểm danh. Khi mỗi buổi được ghi bằng một ký hiệu (C có mặt, P nghỉ có phép, B học bù…), học phí, công nợ và lương giáo viên đều tự tính ra từ đó. Bài đi qua 8 bảng cần có, công thức đếm buổi, 4 cách tính học phí kèm ví dụ số, cách xử lý nghỉ có phép và buổi học bù, phiếu học phí có mã QR, rồi tới lương giáo viên.

Đăng 2026-10-10 · 12 phút đọc · Lớp dạy thêm, Trung tâm, Điểm danh, Học phí, Google Sheets

Video: https://youtu.be/yaBEju1QoYg

## Vì sao sổ điểm danh giấy và Zalo hay lệch tiền

Lớp 10 học sinh thì cuốn sổ là đủ. Khi có 3–4 lớp, mỗi lớp một cách thu (lớp Toán thu theo tháng, lớp Vẽ thu theo buổi, lớp IELTS thu trọn khoá), có học sinh vào giữa tháng, có em nghỉ ốm xin học bù, có hai anh em học hai lớp — cuối tháng ngồi cộng tay là lúc sai. Sai một buổi thì phụ huynh nhắn hỏi, còn sai lương giáo viên thì mất lòng người dạy.

Cách chắc ăn là **chỉ gõ một thứ: điểm danh**. Học phí là phép tính trên số buổi; lương giáo viên là phép tính trên số buổi dạy. Không ai gõ tay số tiền.

- **Số bảng:** 8 (5 gõ tay, 3 tự tính)
- **Ký hiệu điểm danh:** C, M, P, K, B, T
- **Cách tính học phí:** Tháng, buổi, trọn khoá, gói buổi
- **Dùng được trên:** Google Sheets, Excel

## 8 bảng của một file quản lý lớp học

![Tám bảng: Học sinh, Lớp & Bảng giá, Ghi danh, Điểm danh, Thu tiền (viền vàng, gõ tay) và Học phí, Công nợ, Lương giáo viên (viền xanh, tự tính)](https://www.hitava.cloud/img/blog/quan-ly-lop-day-them-bang-google-sheets/cau-truc.webp)
*Bảng vàng gõ tay, bảng xanh chỉ có công thức.*

*Lịch học là bảng thứ 9 nếu có nhiều giáo viên dạy thay nhau; lớp một giáo viên thì có thể bỏ.*

| Bảng | Mỗi dòng là | Cột chính |
|---|---|---|
| Học sinh | Một học sinh | Mã HS, họ tên, phụ huynh, SĐT, **mã gia đình** (anh chị em dùng chung) |
| Lớp & Bảng giá | Một lớp | Mã lớp, giáo viên, lịch, cách tính phí, đơn giá, số buổi chuẩn/tháng, áp dụng từ kỳ |
| Ghi danh | Một học sinh vào một lớp | Mã HS, mã lớp, ngày vào, ngày nghỉ, giảm riêng |
| Lịch học | Một buổi học | Ngày, lớp, GV phân công, GV thực dạy, trạng thái (Đã dạy / Huỷ / Bù) |
| Điểm danh | Một học sinh × một lớp × một tháng | Kỳ, mã HS, lớp, B01…B12 (mỗi ô một buổi) |
| Học phí | Một gia đình × một tháng | Các lớp, giảm, bảo lưu, nợ kỳ trước, phải thu, nội dung chuyển khoản |
| Thu tiền | Một lần nhận tiền | Ngày, mã gia đình, kỳ, số tiền, hình thức |
| Lương giáo viên | Một giáo viên × một tháng | Buổi dạy, dạy thay, đơn giá, thưởng, trừ, thực nhận |

Hai nguyên tắc giống hệt [file quản lý phòng trọ](https://www.hitava.cloud/blog/cach-quan-ly-phong-tro-bang-google-sheets): **mọi tháng nằm chung một bảng** (có cột Kỳ, ví dụ 2026-10), và **đổi giá thì thêm dòng giá mới** có cột "áp dụng từ kỳ", không sửa dòng cũ — tăng học phí từ tháng 11 thì phiếu tháng 10 vẫn giữ nguyên.

## Cách làm bảng điểm danh: ký hiệu và công thức đếm buổi

Bảng Điểm danh: A Kỳ · B Mã HS · C Họ tên · D Lớp · E Cách tính · F đến Q là 12 ô buổi (B01…B12) · từ cột R là công thức. Mỗi buổi gõ một chữ:

| Ký hiệu | Nghĩa | Tính phí? | Tính chuyên cần? |
|---|---|---|---|
| C | Có mặt | Có | Có mặt |
| M | Đi muộn | Có | Có mặt |
| P | Nghỉ có phép (báo trước) | Tuỳ quy định — thường bảo lưu | Vắng |
| K | Nghỉ không phép | Có | Vắng |
| B | Học bù | Thay cho buổi P đã bảo lưu | Có mặt |
| T | Học thử | Không | Không tính |

Chọn F2:Q1000 › Dữ liệu › Xác thực dữ liệu › Menu thả xuống với 6 chữ trên, để không ai gõ "c" thường hay "x". Rồi đếm:

**Số buổi có mặt** (R2) — gồm có mặt, đi muộn, học bù:

```
=COUNTIF(F2:Q2;"C")+COUNTIF(F2:Q2;"M")+COUNTIF(F2:Q2;"B")
```

**Nghỉ có phép** (S2) và **nghỉ không phép** (T2):

```
=COUNTIF(F2:Q2;"P")
=COUNTIF(F2:Q2;"K")
```

**Chuyên cần** (U2) — có mặt chia cho số buổi đã điểm danh, bỏ buổi học thử:

```
=IFERROR(R2/(R2+S2+T2);"")
```

![Bảng điểm danh: mỗi dòng một học sinh trong một lớp, cột cách tính THANG, BUOI, GOI, KHOA, các ô buổi B01 đến B06 ghi C, M, P, cột đếm N, G, C, M, P, K](https://www.hitava.cloud/img/blog/quan-ly-lop-day-them-bang-google-sheets/diem-danh.webp)
*Tab Điểm danh trong mẫu Quản lý lớp học PRO (dữ liệu mẫu). Một học sinh học hai lớp là hai dòng.*

Video: [Điểm danh & học phí lớp dạy thêm, có mã QR (Short)](https://youtu.be/m8E_7QI9YI0)

## 4 cách tính học phí: theo tháng, theo buổi, trọn khoá, gói buổi

![Bốn cách tính học phí với ví dụ số: theo tháng 900.000 × 6/8 = 675.000đ; theo buổi 180.000 × 8 = 1.440.000đ; trọn khoá 7.200.000 chia 2 đợt; gói 12 buổi còn 2 buổi thì nhắc; nghỉ có phép bảo lưu 1.200.000 − 150.000 = 1.050.000đ](https://www.hitava.cloud/img/blog/quan-ly-lop-day-them-bang-google-sheets/hoc-phi.webp)

**Theo tháng.** Học phí cố định mỗi tháng, bất kể tháng có 8 hay 9 buổi. Chỉ cần xử lý học sinh vào giữa tháng: tính theo số buổi còn lại trên số buổi chuẩn của lớp, làm tròn nghìn.

Học phí tháng của học sinh vào giữa tháng (HocPhiThang, SoBuoiChuan lấy từ bảng Lớp; SoBuoiConLai là số buổi từ ngày vào tới cuối tháng):

```
=ROUND(HocPhiThang*MIN(1;SoBuoiConLai/SoBuoiChuan);-3)
```

Ví dụ Toán 6, 900.000đ/tháng, 8 buổi chuẩn, học sinh vào từ buổi thứ 3: 900.000 × 6 / 8 = **675.000đ**. MIN(1;…) giữ cho tháng có 9 buổi vẫn thu đúng 900.000đ chứ không thành 1.012.500đ.

**Theo buổi.** Có hai cách: thu sau (cuối tháng đếm buổi thực học) hoặc thu trước theo số buổi dự kiến rồi bù chênh lệch tháng sau. Thu trước giữ dòng tiền đều hơn:

Phải thu tháng này = buổi dự kiến tháng này − buổi thu thừa tháng trước, nhân đơn giá:

```
=DonGia*(BuoiDuKien - (DuKienThangTruoc - BuoiTinhPhiThangTruoc))
```

Vẽ, 180.000đ/buổi: tháng 9 thu trước 8 buổi = 1.440.000đ, nhưng em nghỉ có phép 1 buổi nên chỉ tính 7. Tháng 10 dự kiến 8 buổi → 180.000 × (8 − (8 − 7)) = **1.260.000đ**.

**Trọn khoá.** Một số tiền cho cả khoá, chia đợt. Mỗi đợt là một dòng phiếu riêng với hạn đóng riêng: IELTS 7.200.000đ chia 2 đợt là 3.600.000đ mỗi đợt.

**Gói buổi.** Phụ huynh mua trước 10, 12 hay 20 buổi, mỗi buổi có mặt trừ một. Cần cảnh báo trước khi hết để phụ huynh gia hạn:

Ở bảng Ghi danh: X2 là số buổi còn lại của gói (trừ buổi có mặt cột R ở mọi tháng của học sinh B2 trong lớp D2), Y2 cảnh báo khi còn ≤ 2:

```
=SoBuoiGoi-SUMIFS('Điểm danh'!R:R;'Điểm danh'!B:B;B2;'Điểm danh'!D:D;D2)
=IF(X2<=2;"Sắp hết gói";"")
```

![Phần tính phí trong tab Điểm danh: đơn giá áp dụng, buổi tính phí, học phí gốc, điều chỉnh vào hoặc nghỉ giữa kỳ, bảo lưu sử dụng, giảm anh chị em, giảm nhiều lớp và thành tiền từng dòng](https://www.hitava.cloud/img/blog/quan-ly-lop-day-them-bang-google-sheets/tinh-hoc-phi.webp)
*Mẫu PRO tính học phí từng bước ngay cạnh điểm danh: điều chỉnh vào giữa kỳ, trừ bảo lưu, giảm anh chị em, giảm học nhiều lớp.*

## Học sinh nghỉ có phép, buổi học bù và giảm anh chị em

Lớp thu theo tháng thường gặp câu hỏi "con nghỉ 2 buổi thì có trừ tiền không". Cần một quy định rõ, ghi trên phiếu đăng ký, và một hạn mức để tránh nghỉ tuỳ ý. Ba lựa chọn hay dùng:

- **Bảo lưu** — buổi nghỉ có phép (trong hạn mức, ví dụ tối đa 2 buổi/tháng) được trừ vào học phí tháng sau.
- **Học bù** — xếp học sinh vào một buổi khác hoặc lớp khác cùng trình độ, ghi B ở ô buổi đó. Đã học bù thì không bảo lưu nữa.
- **Không trừ** — học phí tháng là cố định; ghi rõ từ đầu để phụ huynh không bất ngờ.

**Tiền bảo lưu** trừ vào tháng sau — đơn giá một buổi nhân số buổi nghỉ có phép, tối đa 2, đã trừ buổi học bù:

```
=ROUND(HocPhiThang/SoBuoiChuan*MAX(0;MIN(2;S2-COUNTIF(F2:Q2;"B")));-3)
```

Toán 8, 1.200.000đ/tháng, 8 buổi → 150.000đ một buổi. Em nghỉ có phép 1 buổi, chưa học bù → tháng sau trừ **150.000đ**, phải đóng 1.050.000đ. Nếu đã học bù buổi đó thì MAX(0;MIN(2;1−1)) = 0, không trừ.

**Giảm anh chị em** dựa vào mã gia đình. Ở bảng Học sinh, cột "Con thứ" = =COUNTIF(E$2:E2;E2) (E là mã gia đình) đếm đây là con thứ mấy trong nhà theo thứ tự nhập. Ví dụ quy định giảm 10% từ con thứ hai: Toán 6 của em thứ hai 675.000đ → giảm **67.500đ**.

**Buổi bị huỷ vì giáo viên ốm:** Ghi buổi đó là "Huỷ" ở bảng Lịch học, không xoá. Lớp thu theo buổi thì buổi huỷ không tính phí; lớp thu theo tháng thì phải dạy bù hoặc giảm phí — và buổi huỷ không tính lương giáo viên.

## Phiếu học phí có mã QR và theo dõi công nợ

Phụ huynh có hai con học ba lớp không muốn nhận ba tin nhắn. Gộp **một phiếu cho mỗi gia đình mỗi tháng**: cộng thành tiền các dòng điểm danh cùng mã gia đình, cộng nợ kỳ trước, trừ tiền thừa. Nội dung chuyển khoản theo mẫu cố định "mã gia đình + kỳ", ví dụ **GD0045 202610**, để nhìn sao kê là biết tiền của nhà nào, tháng nào.

Mã QR VietQR ngay trong ô (970436 là mã BIN Vietcombank; K2 số tiền, L2 nội dung chuyển khoản):

```
=IMAGE("https://img.vietqr.io/image/970436-0123456789-compact2.png?amount="&K2&"&addInfo="&ENCODEURL(L2)&"&accountName="&ENCODEURL("TRUNG TAM ABC"))
```

Đổi mã BIN, số tài khoản, tên cho đúng tài khoản của bạn, rồi **quét thử bằng app ngân hàng trước khi gửi phụ huynh** — phải hiện đúng tên chủ tài khoản và số tiền. Cách lấy mã BIN, các mẫu khung QR và lỗi hay gặp ở bài [tạo mã QR chuyển khoản trong Google Sheets](https://www.hitava.cloud/blog/tao-ma-qr-chuyen-khoan-trong-google-sheets).

![Phiếu học phí kỳ 09/2026 gộp cho hai anh em Nguyễn Minh An và Nguyễn Gia Bình: ba lớp, tài liệu, nợ kỳ trước 200.000đ, cần thanh toán 2.858.000đ, thông tin chuyển khoản và mã QR với nội dung GD0045 202609](https://www.hitava.cloud/img/blog/quan-ly-lop-day-them-bang-google-sheets/phieu-hoc-phi-qr.webp)
*Phiếu gộp gia đình trong mẫu PRO (dữ liệu mẫu): trừ bảo lưu, giảm, cộng tài liệu và nợ kỳ trước, mã QR điền sẵn số tiền.*

**Còn nợ** của một gia đình = tổng phiếu − tổng đã thu (nợ nhiều tháng tự cộng dồn):

```
=SUMIFS('Học phí'!K:K;'Học phí'!B:B;A2)-SUMIFS('Thu tiền'!D:D;'Thu tiền'!B:B;A2)
```

Phụ huynh trả thiếu thì cứ ghi đúng số tiền nhận vào bảng Thu tiền; phần thiếu tự thành nợ và hiện ở phiếu tháng sau. Sắp bảng Công nợ theo số tiền giảm dần là có danh sách cần nhắc.

Video: [Tạo mã QR chuyển khoản ngay trong Google Sheets — 1 hàm (Short)](https://youtu.be/JKdgBp0dm1k)

## Cách tính lương giáo viên dạy thêm

Lương giáo viên ở trung tâm nhỏ thường theo một trong năm kiểu: theo buổi, theo giờ, theo phần trăm học phí thực thu của lớp, theo số học sinh có mặt, hoặc lương cứng cộng buổi. Cả năm kiểu đều đếm từ bảng Lịch học.

**Số buổi đã dạy trong tháng** của giáo viên ở A2 — đếm theo cột GV thực dạy (D), chỉ buổi "Đã dạy":

```
=COUNTIFS('Lịch học'!D:D;A2;'Lịch học'!A:A;">="&DauKy;'Lịch học'!A:A;"<="&CuoiKy;'Lịch học'!E:E;"Đã dạy")
```

Vì đếm theo **giáo viên thực dạy** chứ không theo giáo viên phân công, buổi dạy thay tự tính cho người đứng lớp. Ví dụ: cô Hà dạy 12 buổi, đơn giá 280.000đ/buổi → **3.360.000đ**. Theo % thực thu: lớp thu được 13.500.000đ trong tháng, thoả thuận 40% → **5.400.000đ**. Cộng phụ cấp, thưởng, trừ tạm ứng là ra thực nhận.

![Bảng chốt lương giáo viên: mỗi giáo viên một dòng với cách tính theo buổi, theo giờ, theo học sinh có mặt, cứng cộng buổi; số buổi, buổi dạy thay cộng trừ, số giờ, lương, phụ cấp, thực nhận và trạng thái chưa trả](https://www.hitava.cloud/img/blog/quan-ly-lop-day-them-bang-google-sheets/luong-giao-vien.webp)
*Chốt lương trong mẫu PRO (dữ liệu mẫu): cột Thay ghi +1 cho người dạy thay, −1 cho người được thay.*

Giáo viên cộng tác nhận từ một mức nhất định có thể phải khấu trừ thuế thu nhập cá nhân — phần này kiểm tra với kế toán hoặc cơ quan thuế. Cách tính lương, bảo hiểm và thuế cho nhân viên chính thức ở bài [cách tính lương nhân viên bằng Excel](https://www.hitava.cloud/blog/cach-tinh-luong-nhan-vien-bang-excel).

→ [Quản lý lớp học PRO dựng sẵn toàn bộ vòng này: điểm danh 6 ký hiệu, học phí 4 cách tính có bảo lưu, phiếu gộp gia đình có mã QR, thu tiền, công nợ, lương giáo viên 5 cách, điểm số và báo cáo học tập. Trên Google Sheets có thêm mở kỳ tự động, tin Zalo soạn sẵn, PDF, email, đối soát sao kê và Web App để giáo viên điểm danh bằng điện thoại.](https://www.hitava.cloud/san-pham/quan-ly-lop-hoc-pro)

## Vòng việc mỗi tháng của lớp dạy thêm

1. **Mở tháng** — tạo dòng điểm danh cho mỗi ghi danh đang học (và dòng buổi học trong Lịch học nếu dùng).
2. **Điểm danh** — sau mỗi buổi, giáo viên hoặc giáo vụ gõ ký hiệu.
3. **Phát sinh** — buổi huỷ, dạy thay, học bù, tài liệu, giảm giá.
4. **Chốt học phí** — phát phiếu cho từng gia đình, gửi tin kèm mã QR.
5. **Thu tiền** — mỗi lần nhận tiền một dòng; cuối tuần xem Công nợ.
6. **Chốt lương** — đếm buổi dạy, tính lương, ghi đã trả.
7. **Báo cáo** — doanh thu từng lớp, chuyên cần, học sinh nghỉ liên tiếp.

Khoá các cột công thức trước khi chia file cho giáo viên ([cách khoá ô công thức](https://www.hitava.cloud/blog/khoa-o-cong-thuc-google-sheets)), để không ai gõ đè lên học phí hay lương.

|  | Tự dựng theo bài này | Quản lý lớp học PRO |
|---|---|---|
| Điểm danh, đếm buổi | Có | Có, kèm cảnh báo nghỉ liên tiếp |
| Học phí 4 cách, bảo lưu, giảm | Tự viết từng công thức | Có sẵn, đổi quy định ở tab Thiết lập |
| Mã QR, tin Zalo, PDF, email | Làm được phần QR bằng hàm IMAGE | Có sẵn trên Google Sheets (Zalo: chép tin hoặc tải ảnh rồi tự gửi) |
| Giáo viên điểm danh bằng điện thoại | Mở cả file bằng ứng dụng Sheets | Web App riêng, mỗi giáo viên một link + mã PIN |
| Lương giáo viên | Theo buổi, % thực thu | 5 cách, tự đếm dạy thay |
| Chi phí | Miễn phí | Mua một lần |

Dạy một hai lớp, một cách thu: file tự dựng như trên là đủ. Nhiều lớp, nhiều giáo viên, phụ huynh hỏi chuyên cần thường xuyên thì mẫu làm sẵn đỡ nhiều giờ mỗi tháng. Đang cân nhắc với phần mềm quản lý trung tâm thu phí hằng tháng, xem [mẫu Google Sheets hay phần mềm quản lý](https://www.hitava.cloud/so-sanh/mau-google-sheets-hay-phan-mem-quan-ly).

- [Tạo mã QR chuyển khoản trong Google Sheets](https://www.hitava.cloud/blog/tao-ma-qr-chuyen-khoan-trong-google-sheets): Hàm IMAGE, mã BIN, nội dung chuyển khoản
- [Google Sheets hay Excel?](https://www.hitava.cloud/blog/google-sheets-hay-excel): Điện thoại, làm chung, Apps Script
- [Cách quản lý phòng trọ bằng Google Sheets](https://www.hitava.cloud/blog/cach-quan-ly-phong-tro-bang-google-sheets): Cùng cách tổ chức hoá đơn, thu tiền, công nợ
- [Hướng dẫn cài đặt Quản lý lớp học PRO](https://www.hitava.cloud/huong-dan/quan-ly-lop-hoc-pro): Cài Apps Script, thử mã QR, bật Web App

## Câu hỏi thường gặp

**Thu học phí theo tháng hay theo buổi thì tốt hơn?**

Theo tháng dễ quản lý và dòng tiền đều, hợp lớp văn hoá học cố định. Theo buổi công bằng hơn với lớp năng khiếu, học sinh hay nghỉ. Nhiều trung tâm dùng cả hai: chọn theo từng lớp, không phải cho cả trung tâm.

**Giáo viên điểm danh trên điện thoại được không?**

Mở file bằng ứng dụng Google Sheets là gõ được, nhưng giáo viên sẽ thấy cả số điện thoại, học phí của mọi học sinh. Muốn giáo viên chỉ thấy lớp mình, cần một trang điểm danh riêng viết bằng Apps Script — như Web App đi kèm Quản lý lớp học PRO.

**Có tự gửi tin Zalo cho phụ huynh được không?**

Không. Zalo không cho phần mềm tự gửi tin tới tài khoản cá nhân. Cách thực tế là soạn sẵn tin nhắn có số tiền và ảnh phiếu có mã QR, rồi chép dán vào Zalo; phụ huynh có email thì gửi email hàng loạt bằng Apps Script được.

**Dữ liệu học sinh để trên Google Sheets có an toàn không?**

File nằm trong Google Drive của bạn; chỉ người được chia sẻ mới mở được. Hạn chế chia quyền sửa, không để chế độ "bất kỳ ai có đường liên kết", và xin đồng ý của phụ huynh trước khi lưu ảnh, số điện thoại của học sinh.

## Mẫu liên quan

- https://www.hitava.cloud/san-pham/quan-ly-lop-hoc-pro

Trang bài viết: https://www.hitava.cloud/blog/quan-ly-lop-day-them-bang-google-sheets